예스스탁
예스스탁 답변
2026-05-21 12:50:15
안녕하세요
예스스탁입니다.
일봉 분봉 식이 다르지는 않습니다,
거래대금만 일봉이나 분봉에 맞게 지정해 주시면 됩니다.
의도와 다른 부분 있으시면 다시 연락주시기 바랍니다.
1 종목검색
input : P1(20),P2(240),Period(150);
input : 거래대금(200);//억단위
var : vwap(0),vwma(0),mav1(0),mav2(0);
var : mx(0),mn(0),T(0),T1(0),T2(0);
mav1 = ma(c,P1);
mav2 = ma(c,P2);
vwap = AccumN((H+L+C)/3 * V, Period) / AccumN(V, Period);
vwma = AccumN(C * V, Period) / AccumN(V, Period);
mx = max(vwap,vwma);
mn = min(vwap,vwma);
//조건1
Condition1 = mav1 > mav1 and
Money >= 거래대금*100000000 and
C >= DayClose(1)*1.05 and
c > DayOpen;
#종가라 기준선중 큰값을 돌파하면
if T <= 0 and CrossUp(c,mx) Then
{
T = 1; #T는 1
#조건1을 만족했으면 T는 2
if Condition1 == true Then
T = 2;
T1 = T[1]; #T1는 직전구간(데드구간) T값
T2 = T1[1]; #T1 전전구간(직전골드구간) T값
#현재골드봉이고 직전데드구간은 -1로 끝났고 직전골드봉은 조건1이 만족
if T1 == -1 and T2 == 2 Then
Find(1);
}
if T >= 0 and CrossDown(c,mn) Then
T = -1;
#조건2체크 : 데드 구간에서 고가가 기준선 중 작은값보다 크거나 작은 봉이 하나라도 있으면 T는 -1에서 0
if T == -1 and H >= mn Then
T = -2;
2 지표
input : P1(20),P2(240),Period(150);
input : 거래대금(200);//억단위
input : 골드수평선색(red),데드수평선색(blue);
input : 골드수평선굵기(1),데드수평선굵기(1);
input : 골드가격표시색(red),데드가격표시색(blue);
input : 골드가격글자크기(12),데드가격글자크기(12);
input : 골드가격수숫점자리(0),데드가격소숫점자리(0);
var : vwap(0),vwma(0),mav1(0),mav2(0);
var : mx(0),mn(0),T(0),T1(0),T2(0);
var : upv(0),dnv(0),TL1(0),TX1(0),TL2(0),TX2(0);
mav1 = ma(c,P1);
mav2 = ma(c,P2);
vwap = AccumN((H+L+C)/3 * V, Period) / AccumN(V, Period);
vwma = AccumN(C * V, Period) / AccumN(V, Period);
Plot1(vwap,"vwap");
Plot2(vwma,"vwma");
mx = max(vwap,vwma);
mn = min(vwap,vwma);
//조건1
Condition1 = mav1 > mav1 and
Money >= 거래대금*100000000 and
C >= DayClose(1)*1.05 and
c > DayOpen;
#종가라 기준선중 큰값을 돌파하면
if T <= 0 and CrossUp(c,mx) Then
{
T = 1; #T는 1
#조건1을 만족했으면 T는 2
if Condition1 == true Then
T = 2;
T1 = T[1]; #T1는 직전구간(데드구간) T값
T2 = T1[1]; #T1 전전구간(직전골드구간) T값
Plot3(L,"골드(점)");
upv = mx;
TL_Delete(TL1);
TL1 = TL_New(sDate,sTime,upv,NextBarSdate,NextBarStime,upv);
TL_SetDrawMode(TL1,0);
TL_SetExtLeft(TL1,true);
TL_SetExtRight(TL1,true);
TL_SetColor(TL1,골드수평선색);
TL_SetSize(TL1,골드수평선굵기);
Text_Delete(TX1);
TX1 = Text_New(NextBarSdate,NextBarStime,upv,NumToStr(upv,골드가격수숫점자리));
Text_SetStyle(TX1,0,0);
Text_SetColor(TX1,골드가격표시색);
Text_SetSize(TX1,골드가격글자크기);
}
Else
Text_SetLocation(TX1,NextBarSdate,NextBarStime,upv);
if T >= 0 and CrossDown(c,mn) Then
{
T = -1;
Plot4(L,"데드(점)");
dnv = mn;
TL_Delete(TL2);
TL2 = TL_New(sDate,sTime,dnv,NextBarSdate,NextBarStime,dnv);
TL_SetDrawMode(TL2,0);
TL_SetExtLeft(TL2,true);
TL_SetExtRight(TL2,true);
TL_SetColor(TL2,데드수평선색);
TL_SetSize(TL2,데드수평선굵기);
Text_Delete(TX2);
TX2 = Text_New(NextBarSdate,NextBarStime,dnv,NumToStr(dnv,데드가격소숫점자리));
Text_SetStyle(TX2,0,1);
Text_SetColor(TX2,데드가격표시색);
Text_SetSize(TX2,데드가격글자크기);
}
Else
Text_SetLocation(TX2,NextBarSdate,NextBarStime,dnv);
#조건2체크 : 데드 구간에서 고가가 기준선 중 작은값보다 크거나 작은 봉이 하나라도 있으면 T는 -1에서 0
if T == -1 and H >= mn Then
T = -2;
즐거운 하루되세요
