커뮤니티
지표식 하나 부탁드리겠습니다.
2026-06-18 14:10:26
39
글번호 232493
첨부 이미지
그림1
안녕하세요.
항상 감사드립니다.
지표식하나 부탁드리겠습니다.
올린 그림은 MACD 12.26.9 가 교차하면은 그 색을 바탕화면에 색을 나타낸것입니다.
(신호가 골드시에 분홍색으로 데드시에 노란색으로 표시한것입니다.)
올린 그림에서 분홍색이 나온 구간을(10분이던 1분이던 상관없이 1개봉으로 처리) 1개의 봉으로 해서 봉을 만들어 주시면은 감사하겠습니다.
마찬가지로 분홍색 (골드구간)은 빨간색으로,노란색이 나온데드 구간은 파란색 봉으로 만들어 주시면은 감사하겠습니다.
여기서 바탕화면에 분홍색,노란색을 표시할 필요는 없습니다.
감사드립니다.
- 1. ccc.jpg (0.22 MB)
답변 1
예스스탁 예스스탁 답변
2026-06-18 16:15:00
안녕하세요
예스스탁입니다.
Input : shortPeriod(12), longPeriod(26), Period(9);
Var : MACDV(0), MACDS(0);
var : DD(0),TT(0),OO(0),HH(0),LL(0),ii(0);
var : T(0),Box(0),HTL(0),LTL(0);
MACDV = MACD(shortPeriod, longPeriod);
MACDS = ema(MACDV,Period);
Plot1(MACDV, "MACD");
Plot2(MACDS, "MACDSignal");
PlotBaseLine1(0, "기준선1");
if CrossUp(MACDV,MACDS) Then
{
T = 1;
DD = sDate;
TT = sTime;
OO = O;
HH = H;
LL = L;
ii = 0;
Box = Box_New(DD,TT,OO,NextBarSdate,NextBarStime,C);
Box_SetColor(box,Red);
Box_SetSize(box,1);
HTL = TL_New(sDate,sTime,H,sDate,sTime,max(C,OO));
LTL = TL_New(sDate,sTime,L,sDate,sTime,min(C,OO));
TL_SetColor(HTL,Red);
TL_SetColor(LTL,Red);
TL_SetSize(HTL,1);
TL_SetSize(LTL,1);
}
Else if CrossDown(MACDV,MACDS) Then
{
T = -1;
DD = sDate;
TT = sTime;
OO = O;
HH = H;
LL = L;
ii = 0;
Box = Box_New(DD,TT,OO,NextBarSdate,NextBarStime,C);
Box_SetColor(box,Blue);
Box_SetSize(box,1);
HTL = TL_New(sDate,sTime,HH,sDate,sTime,max(C,OO));
LTL = TL_New(sDate,sTime,min(C,OO),sDate,sTime,LL);
TL_SetColor(HTL,Blue);
TL_SetColor(LTL,Blue);
TL_SetSize(HTL,1);
TL_SetSize(LTL,1);
}
Else
{
if T != 0 then
{
ii = ii +1;
if h > hh Then
hh = h;
if l < ll Then
ll = l;
Box_SetEnd(box,NextBarSdate,NextBarStime,c);
TL_SetBegin(HTL,sDate[Floor(ii/2)],sTime[Floor(ii/2)],max(OO,c));
TL_SetEnd(HTL,sDate[Floor(ii/2)],sTime[Floor(ii/2)],HH);
TL_SetBegin(LTL,sDate[Floor(ii/2)],sTime[Floor(ii/2)],min(OO,c));
TL_SetEnd(LTL,sDate[Floor(ii/2)],sTime[Floor(ii/2)],LL);
}
}
즐거운 하루되세요