커뮤니티
수식작성 부탁드립니다.
2026-07-03 13:29:56
89
글번호 232674
운영자님
이번에 부탁드릴 사항은
매수진입/청산 : 상위타임프레임(30분봉 또는 60분봉)의 시가를 상향돌파 시 하위타임프레임(현재봉 1분봉)에서 매수진입하고 n틱 수익 또는 m틱 손실 시 청산.
매도진입/청산 : 상위타임프레임(30분봉 또는 60분봉)의 시가를 하향돌파 시 하위타임프레임(현재봉 1분봉)에서 매도진입하고 n틱 수익 또는 m틱 손실 시 청산.
추가요청사항
1) 진입 시 X틱씩 수익 시 Y틱씩 손절가를 올릴거나 내릴 수 있도록 추적손절매 기능을 추가
2) 진입 신호가 A번째 발생 시 실제 진입 (왜냐하면 시초가를 여러번 터치하는 경우가 많기 때문에 몇번째 터치 시 진입하는 것이 가장 이상적인지 통계를 위해서)
감사합니다.
답변 1
예스스탁 예스스탁 답변
2026-07-03 14:26:32
안녕하세요
예스스탁입니다.
input : 타주기분(60),n(3),n틱수익(50),n틱손실(20),x틱간격(5),손절가Y틱상승(5);
var : S1(0),D1(0),TM(0),TF(0),OO(0);
var : up(0),dn(0);
if Bdate != Bdate[1] Then
{
S1 = TimeToMinutes(stime);
D1 = sdate;
}
if D1 > 0 then
{
if sdate == D1 Then
TM = TimeToMinutes(stime)-S1;
Else
TM = TimeToMinutes(stime)+1440-S1;
TF = TM%타주기분;
if Bdate != Bdate[1] or
(Bdate == Bdate[1] and 타주기분 > 1 and TF < TF[1]) or
(Bdate == Bdate[1] and 타주기분 > 1 and TM >= TM[1]+타주기분) or
(Bdate == Bdate[1] and 타주기분 == 1 and TM > TM[1]) Then
{
OO = O;
up = 0;
dn = 0;
}
if CrossUp(C,OO) Then
{
up = up+1;
if up == n Then
Buy();
}
if CrossDown(C,OO) Then
{
dn = dn+1;
if dn == n Then
Sell();
}
}
if MarketPosition == 1 Then
{
var1 = Floor((highest(H,BarsSinceEntry)-EntryPrice)/(PriceScale*x틱간격));
ExitLong("bp",AtLimit,EntryPrice+PriceScale*n틱수익);
ExitLong("bl",AtStop,EntryPrice-PriceScale*n틱손실+var1*(PriceScale*손절가Y틱상승));
}
if MarketPosition == -1 Then
{
var2 = Floor((EntryPrice-lowest(L,BarsSinceEntry))/(PriceScale*x틱간격));
ExitShort("sp",AtLimit,EntryPrice-PriceScale*n틱수익);
ExitShort("sl",AtStop,EntryPrice+PriceScale*n틱손실-var2*(PriceScale*손절가Y틱상승));
}
즐거운 하루되세요
이전글