커뮤니티
부탁드립니다.
2026-11-18 18:51:40
79
글번호 234231
-글번호 234190 관련입니다.
-항상 친절한 답변 감사드립니다.
-해선 분봉 (예: 5분봉)차트에 타분봉(예: 60분봉) 차트 macd를 표시하는 지표외에 macd oscillator(+/-) 를 표시하는 지표식 부탁 드립니다
답변 1
예스스탁 예스스탁 답변
2026-11-19 10:06:51
안녕하세요
예스스탁입니다.
Input : 분주기(60),short(12),long(26),sig(9);
Var : S1(0),D1(0),TM(0),TF(0),bar(0);
Var : EP1(0),EP2(0),EP3(0);
Var : ema1(0),ema2(0),PreEma1(0),PreEma2(0);
Var : MACDV(0),MACDS(0),PreMACDS(0),macdo(0);
// MACD에 사용할 평활계수
EP1 = 2/(short+1);
EP2 = 2/(long+1);
EP3 = 2/(sig+1);
// 새로운 영업일이 시작하면 시작시간(S1)과 날짜(D1)를 초기화
if Bdate != Bdate[1] Then
{
//첫봉의 stime을 분단위로 변환
S1 = TimeToMinutes(stime);
//첫봉의 날짜를 저장
D1 = sdate;
}
// D1에 날짜가 저장된 이후(영업일 변경이 되는 봉이 발생 후에)
if D1 > 0 then
{
//같은 날짜인지 판단하여 영업일 변경이후 경과분(TM)계산
if sdate == D1 Then
TM = TimeToMinutes(stime)-S1;//첫봉과 동일날짜이면 첫봉부터 경과분계산
Else
TM = TimeToMinutes(stime)+1440-S1;//다음날이면 24시간(1440분)을 더해서 보정
//영업일 변경이후 경과분을 분주기로 나누어 나머지를 구함
TF = TM%분주기;
//새로운 영업일이 시작하거나 새로운 분이 시작되면
if Bdate != Bdate[1] or
(Bdate == Bdate[1] and 분주기 > 1 and TF < TF[1]) or
(Bdate == Bdate[1] and 분주기 > 1 and TM >= TM[1]+분주기) or
(Bdate == Bdate[1] and 분주기 == 1 and TM > TM[1]) Then
{
//다른주기 분봉 갯수 카운트 카운트
bar = bar + 1;
//다른주기 전봉의 EMA와 MACD Signal 값을 저장
PreEma1 = Ema1[1];
PreEma2 = Ema2[1];
PreMACDS = MACDS[1];
}
//다른주기 첫번째 봉에서는
if bar <= 1 then
{
//장단기 EMA는 종가
ema1 = C;
ema2 = C;
//MACD는 단기지수이평-장기지수이평
MACDV = ema1-ema2;
//MACD시그널은 MACD값
MACDS = MACDV;
}
else{ //두번째봉 이후부터는
// 장단기 EMA : 종가 * 평활계수 + 이전EMA * (1-평활계수)
ema1 = C * EP1 + PreEma1 * (1-EP1);
ema2 = C * EP2 + PreEma2 * (1-EP2);
//MACD는 단기지수이평-장기지수이평
MACDV = ema1-ema2;
// MACD 시그널 : MACD * 평활계수 + 전봉MACD시그널 * (1-평활계수)
MACDS = MACDV * EP3 + PreMACDS * (1-EP3);
}
MACDO = MACDV-MACDS;
if MACDO > 0 then
{
plot1(MACDO, "MACDOscillator+");
Plot2(0, "MACDOscillator-");
}
else
{
Plot1(0, "MACDOscillator+");
Plot2(MACDO, "MACDOscillator-");
}
// 차트 출력: MACD 라인, 시그널 라인, 기준선(0)
Plot3(MACDV,"MACD");
Plot4(MACDS,"MACD Signal");
PlotBaseLine1(0);
}
즐거운 하루되세요
다음글
이전글