커뮤니티
갭보정된 지표식좀 부탁드립니다
2010-03-28 02:41:54
818
글번호 28949
갭보정된 볼린저밴드와 파라볼릭 지표식이 가능한가요??
가능하다면 수식좀 부탁드리겠습니다~
항상 감사합니다 ^^
답변 1
예스스탁 예스스탁 답변
2010-03-29 09:14:16
안녕하세요
예스스탁입니다.
1. 갭보정볼린져밴드
Input : Period(20), Dv(8);
Var : value_MA(0),BBUp(0),BBDn(0),sumGap(0), gap(0), GC(0);
if date!=date[1] then { // 날짜가 변경되는 봉에서(분봉에서 첫번째 봉)
gap = Open-Close[1]; // 일간갭
sumGap = sumGap+gap; // 일간갭 누적
}
GC = C - sumGap; // 갭보정 종가
BBUp = ma(GC, Period) + (Dv * std(GC, Period));
BBDn = ma(GC, Period) - (Dv * std(GC, Period));
plot1(Bbup);
plot2(BBdn);
2. 갭보정 파라볼릭
Input: AF(0.02), AFMAX(0.2);
Var : Direction(0), SAR_Value(Close), AF_Value(.02), HighValue(High), LowValue(Low), EP(0),GCSAR(0);
var : gap(0),sumgap(0),GO(0),GH(0),GL(0),GC(0);
if date!=date[1] then { // 날짜가 변경되는 봉에서(분봉에서 첫번째 봉)
gap = Open-Close[1]; // 일간갭
sumGap = sumGap+gap; // 일간갭 누적
}
GO = O - sumGap;// 갭보정 시가
GH = H - sumGap;// 갭보정 고가
GL = L - sumGap;// 갭보정 저가
GC = C - sumGap; // 갭보정 종가
if EP != 0 Then
{
if Direction == 1 then
{
EP = HighValue;
SAR_Value = SAR_Value + AF_Value * (EP - SAR_Value);
if GH > HighValue then
{
HighValue = GH;
AF_Value = AF_Value + AF;
if AF_Value >= AFMAX then AF_Value = AFMAX;
}
if Close < SAR_Value then
{
Direction = -1;
SAR_Value = EP;
AF_Value = 0;
EP = 0;
LowValue = Gl;
}
}
else
{
EP = LowValue;
SAR_Value = SAR_Value + AF_Value * (EP - SAR_Value);
if GL < LowValue then
{
LowValue = GL;
AF_Value = AF_Value + Af;
if AF_Value >= AFMAX then AF_Value = AFMAX;
}
if GC > SAR_Value then
{
Direction = 1;
SAR_Value = EP;
AF_Value = 0;
EP = 0;
HighValue = GH;
}
}
GCSar = SAR_Value;
}
else
{
if SAR_Value != 0 && EP == 0 then
{
if Direction == 1 then
{
EP = HighValue;
AF_Value = AF;
SAR_Value = SAR_Value + AF_Value * (EP - SAR_Value);
if GH > HighValue then
{
HighValue = GH;
AF_Value = AF_Value + AF;
if AF_Value >= AFMAX then AF_Value = AFMAX;
}
}
else
{
EP = LowValue;
AF_Value = Af;
SAR_Value = SAR_Value + AF_Value * (EP - SAR_Value);
if GL < LowValue then
{
LowValue = GL;
AF_Value = AF_Value + AF;
if AF_Value >= AFMAX then AF_Value = AFMAX;
}
}
GCSar = SAR_Value;
}
else
{
if Direction == 0 then
{
if GC > GC[1] then Direction = 1;
else
if GC < GC[1] then Direction = -1;
}
else
{
if Direction == 1 then
{
if GC < GC[1] then
{
Direction = -1;
SAR_Value = HighValue;
GCSar = SAR_Value;
}
}
if Direction == -1 then
{
if GC > GC[1] then
{
Direction = 1;
SAR_Value = LowValue;
GCSar = SAR_Value;
}
}
}
LowValue = min(GL,LowValue);
HighValue = max(GH,HighValue);
}
}
plot1(GCSar);
즐거운 하루되세요
> 몸으로뛴다 님이 쓴 글입니다.
> 제목 : 갭보정된 지표식좀 부탁드립니다
> 갭보정된 볼린저밴드와 파라볼릭 지표식이 가능한가요??
가능하다면 수식좀 부탁드리겠습니다~
항상 감사합니다 ^^
다음글
이전글