커뮤니티
일봉매매에서 주봉이평을 필터링하고 싶은데..
2011-01-03 16:32:38
736
글번호 34689
일봉매매에서 주봉의 이평또는 지수이평을 필터링하고 싶은데 주봉의 이평상승여부를 필터 적용 할려면 어떻게 해야되나요?
즉.
일봉에서 지수이평 5일하고 10일 크로스전략에서
1.매수는 주봉의 13일이평이 상승 중이고 크로스 업일때 들어가고 청산은 크로스 다운.
2.매도는 주봉의 13일이평이 하락 중이고 크로스 다운일때 들어가고 청산은 크로스 업 .일때 하고 싶은데..
아무리 찾아봐도 일봉에서 주봉의 이평, 지수이평 구하는 지표식은 있는데 상승중 하락중을 표현할 길이 없네요..^^
답변부탁드립니다.
답변 1
예스스탁 예스스탁 답변
2011-01-03 18:22:59
안녕하세요
예스스탁입니다.
1. 단순이평
input : weekPeriod(13);
var : weekcnt(0),cnt(0),count(0),Sum1(0),Sum2(0),weekmav1(0),weekmav2(0);
Array : weekC[60](0);
if dayofweek(date) < dayofweek(date[1]) Then{
weekC[1] = C[1];
for cnt = 2 to weekPeriod+1{
weekC[cnt] = weekC[cnt-1][1];
}
}
weekC[0] = C;
sum1 = 0;
sum2 = 0;
for count = 0 to weekPeriod {
if count < weekPeriod Then
Sum1 = sum1+WeeKC[count];
if count > 0 Then
Sum2 = sum2+WeeKC[count];
}
weekmav1 = sum1/weekPeriod;#현재주
weekmav2 = sum2/weekPeriod;#이전주
if weekmav1 > weekmav2 Then{
if crossup(ema(c,5),ema(c,10)) Then
buy();
if crossdown(ema(c,5),ema(c,10)) Then
ExitLong();
}
if weekmav1 < weekmav2 Then{
if CrossDown(ema(c,5),ema(c,10)) Then
Sell();
if CrossUp(ema(c,5),ema(c,10)) Then
ExitShort();
}
2. 지수이평
Input : Period(13);
Var : Ep(0), JISU(0), DINDEX(0), PreJISU(0);
Ep = 2/(Period+1);
if dayofweek(date) < dayofweek(date[1]) then {
DINDEX = DINDEX + 1;
PreJISU = JISU[1];
}
if DINDEX <= 1 then
JISU = C;
else
JISU = C * EP + PreJISU * (1-EP);
if JISU > PreJISU Then{
if crossup(ema(c,5),ema(c,10)) Then
buy();
if crossdown(ema(c,5),ema(c,10)) Then
ExitLong();
}
if JISU < PreJISU Then{
if CrossDown(ema(c,5),ema(c,10)) Then
Sell();
if CrossUp(ema(c,5),ema(c,10)) Then
ExitShort();
}
참고하시기 바랍니다.
즐거운 하루되세요
> 오리만두 님이 쓴 글입니다.
> 제목 : 일봉매매에서 주봉이평을 필터링하고 싶은데..
> 일봉매매에서 주봉의 이평또는 지수이평을 필터링하고 싶은데 주봉의 이평상승여부를 필터 적용 할려면 어떻게 해야되나요?
즉.
일봉에서 지수이평 5일하고 10일 크로스전략에서
1.매수는 주봉의 13일이평이 상승 중이고 크로스 업일때 들어가고 청산은 크로스 다운.
2.매도는 주봉의 13일이평이 하락 중이고 크로스 다운일때 들어가고 청산은 크로스 업 .일때 하고 싶은데..
아무리 찾아봐도 일봉에서 주봉의 이평, 지수이평 구하는 지표식은 있는데 상승중 하락중을 표현할 길이 없네요..^^
답변부탁드립니다.