커뮤니티
수식작성 부탁드립니다.
2011-02-09 22:02:36
706
글번호 35585
수고가 많으십니다.
시스템식 작성부탁드립니다.
1. 15분봉을 사용하여 매매
2. 매수: 일봉기준으로 60,120이평 골든크로스 이후 분봉이 일봉의 20이평 돌파하고
스토캐스틱 조건만족시 매수
3. 매도: 10%하락시 손절, 10%상승시 이익실현
4. 재매수: 1) 손절시 2번과 같은 조건 발생시 매수
2) 이익실현시 일봉의 20일 최고가 돌파시 매수
5. 매도: 3번과 같음
6. 재매수: 손절, 이익실현 관계없이 4.2)조건 발생시 매수
스토캐스틱 조건: 1일전, 2일전, 3일전 종가 slowk(5,3) 3개 값중 최저값이 30이하일경우
미리감사드립니다.
답변 1
예스스탁 예스스탁 답변
2011-02-10 13:25:09
안녕하세요
예스스탁입니다.
input : P1(20),P2(60),P3(120);
input : Period(5), Period1(3), Period2(3);
var : count(0), highVal(0), lowVal(0), StoFastK(0), StoK(0), StoD(0);
var : Ep(0), EP1(0), JISU(0), DINDEX(0), PreStoK(0), PreStoD(0);
var : Stok1(0),stok2(0),stok3(0),HH(0);
var : macnt(0),Sum1(0),sum2(0),mav1(0),mav2(0),mav3(0),sum3(0);
#일봉 이평계산
sum1 = 0;
sum2 = 0;
sum3 = 0;
HH = dayhigh(1);
for macnt = 0 to P3{
if macnt < P1 Then
sum1 =sum1+DayClose(macnt);
if macnt < P2 Then
sum2 =sum2+DayClose(macnt);
if macnt < P3 Then
sum3 =sum3+DayClose(macnt);
if dayhigh(macnt) > HH and macnt > 0 and macnt <=20 Then
HH = dayhigh(macnt);
}
mav1 = sum1/P1;
mav2 = sum2/P2;
mav3 = sum3/P3;
##일봉 스토케스틱 계산
#### 특정 구간의 고가 [highest(H,Period)] ####
highVal = dayhigh(0);
for count = 0 to Period-1 {
if dayHigh(count) > highVal then
highVal = dayhigh(count);
}
#### 특정 구간의 저가 [lowest(L,Period)] ####
lowVal = daylow(0);
for count = 0 to Period-1 {
if dayLow(count) < lowVal then
lowVal = dayLow(count);
}
#### Fast StochasticsK ####
StoFastK = (C-lowVal)/(highVal-lowVal)*100;
#### Slow StochasticsK ####
Ep = 2/(Period1+1);
#### Slow StochasticsD ####
Ep1 = 2/(Period2+1);
if date != date[1] then {
DINDEX = DINDEX + 1;
PreStoK = StoK[1];
}
if DINDEX <= 1 then
StoK = StoFastK ;
else
StoK = StoFastK * EP + PreStoK * (1-EP);
if date != date[1] then {
DINDEX = DINDEX + 1;
PreStoD = StoD[1];
}
if DINDEX <= 1 then
StoD = StoK ;
else
StoD = StoK * EP1 + PreStoD * (1-EP1);
if dayindex == 0 Then{
stok1 = stok[1];
stok2 = stok1[1];
stok3 = stok2[1];
}
var : entrycount(0),entrycnt(0);
entrycount = 0;
for entrycnt = 0 to 10{
if sdate == EntryDate(entrycnt) Then
entrycount =entrycount+1;
}
if entrycount == 0 and crossup(c,mav1) and mav2 > mav3 and min(stok1,stok2,stok3) < 30 Then
buy();
if entrycount == 1 Then{
if IsExitName("StopProfittarget",1) == true and MarketPosition == 0 and crossup(c,HH) Then
buy();
if IsExitName("Stoploss",1) == true and crossup(c,mav1) and mav2 > mav3 and min(stok1,stok2,stok3) < 30 Then
buy();
}
if entrycount == 2 Then{
if MarketPosition == 0 and crossup(c,HH) Then
buy();
}
SetStopLoss(10);
SetStopProfittarget(10);
즐거운 하루되세요
> 뮬란 님이 쓴 글입니다.
> 제목 : 수식작성 부탁드립니다.
> 수고가 많으십니다.
시스템식 작성부탁드립니다.
1. 15분봉을 사용하여 매매
2. 매수: 일봉기준으로 60,120이평 골든크로스 이후 분봉이 일봉의 20이평 돌파하고
스토캐스틱 조건만족시 매수
3. 매도: 10%하락시 손절, 10%상승시 이익실현
4. 재매수: 1) 손절시 2번과 같은 조건 발생시 매수
2) 이익실현시 일봉의 20일 최고가 돌파시 매수
5. 매도: 3번과 같음
6. 재매수: 손절, 이익실현 관계없이 4.2)조건 발생시 매수
스토캐스틱 조건: 1일전, 2일전, 3일전 종가 slowk(5,3) 3개 값중 최저값이 30이하일경우
미리감사드립니다.
다음글