커뮤니티
문의입니다...
2011-03-13 12:11:06
683
글번호 36505
타종목 참조 관련 문의입니다.
전략식에서는 기준봉과 참조봉을 모두 열어놓아야 data2에 대한 적용이 가능한데
기준봉에 참조봉을 열지 않고도 상위분봉의 지표라인을 올릴수 있는지를 알고 싶습니다.
즉, 5분봉에서 15분봉의 MACD나 RSI값의 지표를 넣어서 볼수 있는지 알고 싶습니다.
확인부탁드려요..
감사합니다...
답변 1
예스스탁 예스스탁 답변
2011-03-14 13:08:34
안녕하세요
예스스탁입니다.
가능한 지표식도 있고 가능하지 않은 경우도 있습니다.
또한 지수이평이 근간이 되는 지표의 경우 지수이평의
특성상 사용되는 봉의 갯수에 값이 영향을 받기 때문에
값이 다를 수 있으므로 유의하시기 바랍니다.
아래는 MACD입니다.
Input : Atime(15),Period1(12),Period2(26),Period3(9);
Var : Ep1(0), JISU1(0), DINDEX1(0), PreJISU1(0);
Var : Ep2(0), JISU2(0), PreJISU2(0);
Var : Ep3(0), JISU3(0), PreJISU3(0);
var : MACDv(0),MACDS(0);
Ep1 = 2/(Period1+1);
Ep2 = 2/(Period2+1);
Ep3 = 2/(Period3+1);
var1 = TimeToMinutes(stime)%Atime;
if dayindex() == 0 or var1 < var1[1] Then{
DINDEX1 = DINDEX1 + 1;
PreJISU1 = JISU1[1];
PreJISU2 = JISU2[1];
if Dindex1 >= 2 Then
PreJISU3 = JISU3[1];
}
if DINDEX1 <= 1 then {
JISU1 = C;
JISU2 = C;
}
else{
JISU1 = C * EP1 + PreJISU1 * (1-EP1);
JISU2 = C * EP2 + PreJISU2 * (1-EP2);
}
if DINDEX1 <= 2 then {
JISU3 = Jisu1-jisu2;
}
else{
JISU3 = MACDV * EP3 + PreJISU3 * (1-EP3);
}
MACDV = JiSu1-Jisu2;
plot1(MACDV);
plot2(Jisu3);
아래는 RSI입니다.
Inputs:Atime(15), Length(9);
Variables: Counter(0), DownAmt(0), UpAmt(0), UpSum(0), DownSum(0), UpAvg(0), DownAvg(0), RSI(0);
var : Dindex(0), PreUpAvg(0), preDownAvg(0),cnt1(0);
Array : CC[100](0);
var1 = TimeToMinutes(stime)%Atime;
if dayindex() == 0 or var1 <= var1[1] Then{
CC[1] = C[1];
for cnt1 = 2 to 99{
CC[cnt1] = CC[cnt1-1][1];
}
PreUpAvg = UpAvg[1];
preDownAvg = DownAvg[1];
Dindex = dindex + 1;
}
CC[0] = C;
If Dindex == Length Then Begin
UpSum = 0;
DownSum = 0;
For Counter = 0 To Length - 1 Begin
UpAmt = C[Counter] - C[Counter+1];
If UpAmt >= 0 Then
DownAmt = 0;
Else Begin
DownAmt = -UpAmt;
UpAmt = 0;
End;
UpSum = UpSum + UpAmt;
DownSum = DownSum + DownAmt;
End;
UpAvg = UpSum / Length;
DownAvg = DownSum / Length;
End
If Dindex > Length Then {
UpAmt = CC[0]-Cc[1];
If UpAmt >= 0 Then
DownAmt = 0;
Else
{
DownAmt = -UpAmt;
UpAmt = 0;
}
if Dindex <=1 Then {
UpAvg = 1;
DownAvg = 1;
}
Else {
UpAvg = (PreUpAvg * (Length - 1) + UpAmt) / Length;
DownAvg = (preDownAvg * (Length - 1) + DownAmt) / Length;
}
}
If UpAvg + DownAvg <> 0 Then
RSI = 100 * UpAvg / (UpAvg + DownAvg);
Else
RSI = 0;
plot1(RSI,"RSI");
PlotBaseLine1(30, "기준선 30", gray);
PlotBaseLine2(70, "기준선 70", gray);
즐거운 하루되세요
> 아이리스 님이 쓴 글입니다.
> 제목 : 문의입니다...
> 타종목 참조 관련 문의입니다.
전략식에서는 기준봉과 참조봉을 모두 열어놓아야 data2에 대한 적용이 가능한데
기준봉에 참조봉을 열지 않고도 상위분봉의 지표라인을 올릴수 있는지를 알고 싶습니다.
즉, 5분봉에서 15분봉의 MACD나 RSI값의 지표를 넣어서 볼수 있는지 알고 싶습니다.
확인부탁드려요..
감사합니다...
다음글
이전글