커뮤니티
수식작성 부탁드립니다
2011-06-16 10:51:45
750
글번호 39826
항상노고에 감사를 드립니다
1. 어떤 시스템에서 평소에는 09 : 10분 부터 시스템이 작동이 되고
만약 전일 종가 대비 3포인트 이상 갭상승 또는 갭하락시에는 09 : 30분부터
시스템이 작동 되게 하려고 합니다.
2. 아래의 DMI이평 지표식에서 갭보정용 지표식 부탁합니다
input : Period(14), emaPeriod(10);
var : P이평(0), M이평(0);
P이평 = ema(DIPlus(Period), emaPeriod); //PDI의 10일 이평
M이평 = ema(DIMinus(Period), emaPeriod); //MDI의 10일 이평
Plot1(p이평);
Plot2(m이평);
감사드립니다.
답변 1
예스스탁 예스스탁 답변
2011-06-16 11:49:32
안녕하세요
예스스탁입니다.
1.
((abs(dayopen-DayClose(1)) >= 3 and stime >= 93000) or (abs(dayopen-DayClose(1)) < 3 and stime >= 91000))
위표현식을 진입식에 추가하시면 됩니다.
2.
Inputs: Period(10),emaPeriod(10);
var : sumGap(0), gap(0), GO(0), GH(0), GL(0), GC(0),TH(0),TL(0),TR(0);
Var : Counter(0), TRange(0), MyRange(Period), PlusDM14(0), PlusDM(0), MinusDM(0),DPlus(0);
Var : MinusDM14(0), Dminus(0),DMIv(0), ADXCounter(0), ADXCummDMI(0), ADXReturn(0),Return(0),GADX(0);
if date!=date[1] then { // 날짜가 변경되는 봉에서(분봉에서 첫번째 봉)
gap = Open-Close[1]; // 일간갭
sumGap = sumGap+gap; // 일간갭 누적
}
GO = O - sumGap;// 갭보정 시가
GH = H - sumGap;// 갭보정 고가
GL = L - sumGap;// 갭보정 저가
GC = C - sumGap; // 갭보정 종가
If GC[1] > GH then
TH = GC[1];
else
TH = GH;
If GC[1] < GL then
TL = GC[1];
else
TL = GL;
TR = TH - TL;
If CurrentBar == 1 Then {
MyRange = Period;
DPlus = 0;
PlusDM14 = 0;
MinusDM14 = 0;
TRange = 0;
For Counter = 0 To MyRange - 1 {
If GH[Counter] - GH[Counter+1] < 0 Then
PlusDM = 0;
Else
PlusDM = GH[Counter] - GH[Counter+1];
If GL[Counter+1] - GL[Counter] < 0 Then
MinusDM = 0;
Else
MinusDM = GL[Counter+1] - GL[Counter];
If MinusDM >= PlusDM Then
PlusDM = 0;
If PlusDM >= MinusDM Then
MinusDM = 0;
TRange = TRange + TR[Counter];
PlusDM14 = PlusDM14 + PlusDM;
MinusDM14 = MinusDM14 + MinusDM;
}
If TRange <> 0 Then
DPlus = 100 * PlusDM14 / TRange;
Else
DPlus = 0 ;
If TRange <> 0 Then
DMinus = 100 * MinusDM14 / TRange;
Else
DMinus = 0;
}
##dp
Else
If CurrentBar > 1 Then {
If GH[0] - GH[1] < 0 Then
PlusDM = 0;
Else
PlusDM = GH[0] - GH[1];
If GL[1] - GL[0] < 0 Then
MinusDM = 0;
Else
MinusDM = GL[1] - GL[0];
If MinusDM >= PlusDM Then
PlusDM = 0;
If PlusDM >= MinusDM Then
MinusDM = 0 ;
If MyRange > 0 Then Begin
TRange = TRange[1] - (TRange[1] / MyRange) + TR;
PlusDM14 = PlusDM14[1] - (PlusDM14[1] / MyRange) + PlusDM;
MinusDM14 = MinusDM14[1] - (MinusDM14[1] / MyRange) + MinusDM;
End;
If TRange <> 0 Then
DPlus = 100 * PlusDM14 / TRange;
Else
DPlus = 0 ;
If TRange <> 0 Then
DMinus = 100 * MinusDM14 / TRange;
Else
DMinus = 0;
}
plot2(ema(Dplus,emaPeriod));
plot3(ema(Dminus,emaPeriod));
즐거운 하루되세요
> 버핏과소로스 님이 쓴 글입니다.
> 제목 : 수식작성 부탁드립니다
> 항상노고에 감사를 드립니다
1. 어떤 시스템에서 평소에는 09 : 10분 부터 시스템이 작동이 되고
만약 전일 종가 대비 3포인트 이상 갭상승 또는 갭하락시에는 09 : 30분부터
시스템이 작동 되게 하려고 합니다.
2. 아래의 DMI이평 지표식에서 갭보정용 지표식 부탁합니다
input : Period(14), emaPeriod(10);
var : P이평(0), M이평(0);
P이평 = ema(DIPlus(Period), emaPeriod); //PDI의 10일 이평
M이평 = ema(DIMinus(Period), emaPeriod); //MDI의 10일 이평
Plot1(p이평);
Plot2(m이평);
감사드립니다.
다음글