커뮤니티
수식 문의
2011-09-23 10:46:46
537
글번호 42939
보조지표에 로그를 적용하고 싶습니다.
RSI, 스토케스틱 지표에 로그를 적용한 수식을 부탁드립니다.
감사합니다.
답변 1
예스스탁 예스스탁 답변
2011-09-23 14:15:32
안녕하세요
예스스탁입니다.
1.
Input : Length(9);
Var : Counter(0), DownAmt(0), UpAmt(0), UpSum(0), DownSum(0), UpAvg(0), DownAvg(0),Logc(0),RSIv(0);
Logc = log(c);
If CurrentBar == 1 AND Length > 0 Then Begin
UpSum = 0;
DownSum = 0;
For Counter = 0 To Length - 1 Begin
UpAmt = Logc[Counter] - Logc[Counter+1];
If UpAmt >= 0 Then
DownAmt = 0;
Else Begin
DownAmt = -UpAmt;
UpAmt = 0;
End;
UpSum = UpSum + UpAmt;
DownSum = DownSum + DownAmt;
End;
UpAvg = UpSum / Length;
DownAvg = DownSum / Length;
End
Else
If CurrentBar > 1 AND Length > 0 Then Begin
UpAmt = Logc[0] - Logc[1];
If UpAmt >= 0 Then
DownAmt = 0;
Else Begin
DownAmt = -UpAmt;
UpAmt = 0;
End;
UpAvg = (UpAvg[1] * (Length - 1) + UpAmt) / Length;
DownAvg = (DownAvg[1] * (Length - 1) + DownAmt) / Length;
End;
If UpAvg + DownAvg <> 0 Then
RSIv = 100 * UpAvg / (UpAvg + DownAvg);
Else
RSIv = 0;
plot1(RSIv);
PlotBaseLine1(30, "기준선1");
PlotBaseLine2(70, "기준선2");
2.
Input : Period(12), Period1(5), Period2(5);
var : Logc(0),logh(0),logl(0),fk(0),SK(0),SD(0),Value_Lowest(0),Value_Highest(0);
LogC = log(c);
LogH = log(H);
LogL = log(L);
Value_Lowest = Lowest(logL, Period);
Value_Highest = Highest(logH, Period);
FK = (LogC - Value_Lowest) / (Value_Highest - Value_Lowest) * 100;
SK = ema(FK,Period1);
SD = ema(SK,Period2);
Plot1(SK, "StochasticsK");
Plot2(SD, "StochasticsD");
PlotBaseLine1(20, "기준선1");
PlotBaseLine2(80, "기준선2");
즐거운 하루되세요
> 부똘이 님이 쓴 글입니다.
> 제목 : 수식 문의
>
보조지표에 로그를 적용하고 싶습니다.
RSI, 스토케스틱 지표에 로그를 적용한 수식을 부탁드립니다.
감사합니다.
다음글
이전글