커뮤니티
MACD 오실레이터
2011-10-22 16:19:57
475
글번호 43993
죄송합니다만 macd 오실레이터에 적용하는 파라볼릭 수식 좀 만들어 주시면 고맙겠습니다.
제가 (가격)파라볼릭을 수정해서 해볼라니 도저히 안되어서 부탁드립니다.
답변 1
예스스탁 예스스탁 답변
2011-10-24 11:22:46
안녕하세요
예스스탁입니다.
문의하신 내용이 MACD 오실레이터를 기준으로하는 파라볼릭식을
의미하신다면 아래의 식을 사용하시면 됩니다.
Input : P1(12),P2(26),P3(9),AF(0.02), AFMAX(0.2);
Var : Direction(0), SAR_Value(var1), AF_Value(.02), HighValue(var1), LowValue(var1), EP(0),Sarv(0);
var1 = MACD_OSC(P1,P2,P3);
if EP != 0 Then
{
if Direction == 1 then
{
EP = HighValue;
SAR_Value = SAR_Value + AF_Value * (EP - SAR_Value);
if var1 > HighValue then
{
HighValue = var1;
AF_Value = AF_Value + AF;
if AF_Value >= AFMAX then AF_Value = AFMAX;
}
if var1 < SAR_Value then
{
Direction = -1;
SAR_Value = EP;
AF_Value = 0;
EP = 0;
LowValue = var1;
}
}
else
{
EP = LowValue;
SAR_Value = SAR_Value + AF_Value * (EP - SAR_Value);
if var1 < LowValue then
{
LowValue = var1;
AF_Value = AF_Value + Af;
if AF_Value >= AFMAX then AF_Value = AFMAX;
}
if var1 > SAR_Value then
{
Direction = 1;
SAR_Value = EP;
AF_Value = 0;
EP = 0;
HighValue = var1;
}
}
Sarv = SAR_Value;
}
else
{
if SAR_Value != 0 && EP == 0 then
{
if Direction == 1 then
{
EP = HighValue;
AF_Value = AF;
SAR_Value = SAR_Value + AF_Value * (EP - SAR_Value);
if var1 > HighValue then
{
HighValue = var1;
AF_Value = AF_Value + AF;
if AF_Value >= AFMAX then AF_Value = AFMAX;
}
}
else
{
EP = LowValue;
AF_Value = Af;
SAR_Value = SAR_Value + AF_Value * (EP - SAR_Value);
if var1 < LowValue then
{
LowValue = var1;
AF_Value = AF_Value + AF;
if AF_Value >= AFMAX then AF_Value = AFMAX;
}
}
Sarv = SAR_Value;
}
else
{
if Direction == 0 then
{
if var1 > var1[1] then Direction = 1;
else
if var1 < var1[1] then Direction = -1;
}
else
{
if Direction == 1 then
{
if var1 < var1[1] then
{
Direction = -1;
SAR_Value = HighValue;
Sarv = SAR_Value;
}
}
if Direction == -1 then
{
if var1 > var1[1] then
{
Direction = 1;
SAR_Value = LowValue;
Sarv = SAR_Value;
}
}
}
LowValue = min(var1, LowValue);
HighValue = max(var1, HighValue);
}
}
plot1(var1,"MACD오실레이터");
plot2(Sarv,"파라볼릭");
PlotBaseLine1(0);
파라볼릭은 막대그래프로 설정하시면 됩니다.
즐거운 하루되세요
> 노름재이 님이 쓴 글입니다.
> 제목 : MACD 오실레이터
> 죄송합니다만 macd 오실레이터에 적용하는 파라볼릭 수식 좀 만들어 주시면 고맙겠습니다.
제가 (가격)파라볼릭을 수정해서 해볼라니 도저히 안되어서 부탁드립니다.