커뮤니티
수정해주세요----
2012-03-01 18:42:02
494
글번호 48423
Input : Period(30), Period1(15), Period2(15);
var : StoK(0),StoD(0);
StoK = StochasticsK(Period,Period1);
StoD = StochasticsD(Period,Period1,Period2);
Plot1(StoK, "StochasticsK",iff(stok>stok[1],red,IFF(stok<stok[1],BLUE,WHITE)));
Plot2(StoD, "StochasticsD");
PlotBaseLine1(10, "기준선20");
PlotBaseLine2(90, "기준선80");
분봉으로 사용할때 Period 값에 도달할때 까지는 당일봉만 참고하여 계산하게해주세요
답변 1
예스스탁 예스스탁 답변
2012-03-02 12:55:42
안녕하세요
예스스탁입니다
스토케스틱은 기본평균방법으로 지수이동평균을 사용하는 타입니다.
지수이동평균은 과거봉의 결과가 현재봉에 영향을 주는 타입니다.
문의하신 부분은 어떤 방식으로 작성해 드려야 할지 모르겠습니다.
작성한다면 아래식 정도로 작성될 수 있습니다.
Input : Period(30),Period1(15),Period2(15);
Var : Value_Lowest(0), Value_Highest(0),FstK(0),Stok(0),StoD(0),Ep1(0),Ep2(0);
Ep1 = 2/(Period1+1);
Ep2 = 2/(Period2+1);
if dayindex < Period Then{
Value_Lowest = Lowest(L, dayindex+1);
Value_Highest = Highest(H, dayindex+1);
}
Else{
Value_Lowest = Lowest(L, Period);
Value_Highest = Highest(H, Period);
}
FstK = (Close - Value_Lowest) / (Value_Highest - Value_Lowest) * 100;
if dayindex < 1 Then
Stok = FstK;
else
Stok = FstK * EP1 + Stok[1] * (1-EP1);
if dayindex < 2 Then
Stod = Stok;
else
Stod = stok * EP2 + Stod[1] * (1-EP2);
Plot1(StoK, "StochasticsK",iff(stok>stok[1],red,IFF(stok<stok[1],BLUE,WHITE)));
Plot2(StoD, "StochasticsD");
PlotBaseLine1(10, "기준선20");
PlotBaseLine2(90, "기준선80");
즐거운 하루되세요
> leekss1 님이 쓴 글입니다.
> 제목 : 수정해주세요----
> Input : Period(30), Period1(15), Period2(15);
var : StoK(0),StoD(0);
StoK = StochasticsK(Period,Period1);
StoD = StochasticsD(Period,Period1,Period2);
Plot1(StoK, "StochasticsK",iff(stok>stok[1],red,IFF(stok<stok[1],BLUE,WHITE)));
Plot2(StoD, "StochasticsD");
PlotBaseLine1(10, "기준선20");
PlotBaseLine2(90, "기준선80");
분봉으로 사용할때 Period 값에 도달할때 까지는 당일봉만 참고하여 계산하게해주세요
다음글