커뮤니티
최고 손실시손절매
2012-03-31 23:30:10
336
글번호 49572
SetStopLoss 함수를 써서 일정손실이 나면 손절매가 나가는데,
예를 들어 SetStopLoss(3,2) 로 세팅한다면,
하루에 여러번 손실이 날때, SetStopLoss함수는 각 매매 마다 각각 3포인트 손실날때 마다
손절매가 나가는데,
하루에 여러번 매매가 될때 총손실(손실누적)이 4포인트가 되면 청산되고, 다음매매도
진입 않게 하려면 어떻게 해야합니까?
답변 1
예스스탁 예스스탁 답변
2012-04-02 09:54:12
input : 하루손실(4);
var : PLR(0),XCommission(0),XSlippage(0),OpenPL(0),dayPL(0),count(0);
#당일누적손익계산 시작
XCommission = ((C*ExitCommission)/100)*CurrentContracts; #%설정
XSlippage = (ExitSlippage)*CurrentContracts; #Pt설정
PLR = 0;
count = 0;
for var1 = 1 to 10{
if sdate == EntryDate(var1) Then{
count = count+1;
PLR = PLR+PositionProfit(var1);
}
}
if MarketPosition() == 0 Then{
OpenPL = 0;
dayPL = PLR;
}
Else{
OpenPL = (PositionProfit-(XCommission+XSlippage));
dayPL = PLR+OpenPL;
}
if dayPL > -하루손실 then{
if crossup(c,ma(c,20)) Then
buy();
if CrossDown(c,ma(c,20)) Then
Sell();
}
if MarketPosition == 1 Then{
ExitLong("bx1",AtStop,EntryPrice+(-(하루손실)-(PLR)));
}
if MarketPosition == -1 Then{
ExitShort("sx1",AtStop,EntryPrice+((하루손실)+(PLR)));
}
SetStopLoss(3.2);
SetStopEndofday(150000);
즐거운 하루되세요
> 개인투자자 님이 쓴 글입니다.
> 제목 : 최고 손실시손절매
> SetStopLoss 함수를 써서 일정손실이 나면 손절매가 나가는데,
예를 들어 SetStopLoss(3,2) 로 세팅한다면,
하루에 여러번 손실이 날때, SetStopLoss함수는 각 매매 마다 각각 3포인트 손실날때 마다
손절매가 나가는데,
하루에 여러번 매매가 될때 총손실(손실누적)이 4포인트가 되면 청산되고, 다음매매도
진입 않게 하려면 어떻게 해야합니까?
다음글
이전글