커뮤니티
문의드립니다.
2012-04-30 10:34:45
493
글번호 50611
1. 3가지부탁드립니다.
갭보정 Slow 스톡
data2갭보정 Slow 스톡
data2갭보정 MACD 오실레이터(기준선위 빨강,아래 파랑)
2. 일반차트에서 갭보정이평이 필요하네요.
(입력변수는 5,20,60,120,240)
갭보정단순이평
갭보정가중이평
갭보정지수이평
각각 부탁드립니다.
수고하세요.
답변 1
예스스탁 예스스탁 답변
2012-04-30 12:34:38
안녕하세요
예스스탁입니다.
1. 갭보정 스토케스틱(슬로우k,슬로우D)
input : Period(12), Period1(5), Period2(5);
var : sumGap(0), gap(0), GO(0), GH(0), GL(0), GC(0);
var : stoLval(0), stoHval(0), fstK(0), stoK(0), stoD(0);
if date!=date[1] then { // 날짜가 변경되는 봉에서(분봉에서 첫번째 봉)
gap = Open-Close[1]; // 일간갭
sumGap = sumGap+gap; // 일간갭 누적
}
GO = O - sumGap;// 갭보정 시가
GH = H - sumGap;// 갭보정 고가
GL = L - sumGap;// 갭보정 저가
GC = C - sumGap; // 갭보정 종가
stoLval = lowest(GL,Period);
stoHval = highest(GH,Period);
fstK = (GC-stoLval)/(stoHval-stoLval)*100;
stoK = ema(fstK, Period1);
stoD = ema(StoK, Period2);
plot1(stoK,"갭보정 %K");
plot2(stoD,"갭보정 %D");
plotBaseline1(20, "기준선1");
plotBaseline2(80, "기준선2");
2. data2 슬로우 스토케스틱
input : Period(12), Period1(5), Period2(5);
var : sumGap(0,data2), gap(0,data2), GO(0,data2), GH(0,data2), GL(0,data2), GC(0,data2);
var : stoLval(0,data2), stoHval(0,data2), fstK(0,data2), stoK(0,data2), stoD(0,data2);
if data2(date!=date[1]) then {
gap = data2(Open-Close[1]);
sumGap = sumGap+gap;
}
GO = data2(O - sumGap);
GH = data2(H - sumGap);
GL = data2(L - sumGap);
GC = data2(C - sumGap);
stoLval = data2(lowest(GL,Period));
stoHval = data2(highest(GH,Period));
fstK = data2((GC-stoLval)/(stoHval-stoLval)*100);
stoK = data2(ema(fstK, Period1));
stoD = data2(ema(StoK, Period2));
plot1(stoK,"갭보정 %K");
plot2(stoD,"갭보정 %D");
plotBaseline1(20, "기준선1");
plotBaseline2(80, "기준선2");
3.data2 갭보정 MACD오실레이터
input : sp(12), lp(26), period(9);
var : sumGap(0,data2), gap(0,data2), GC(0,data2);
var : MacdVal(0,data2), MacdSig(0,data2),MACDOSC(0,data2);
if data2(date!=date[1]) then {
gap = data2(Open-Close[1]);
sumGap = sumGap+gap;
}
GC = data2(C - sumGap);
MacdVal = data2(ema(GC,sP)-ema(GC,lP)); //macd 지표
MacdSig = data2(ema(MacdVal, Period)); //macd signal 지표
MACDOSC = MacdVal-MacdSig;#MACD 오실레이터
plot1(MACDOSC, "Macd오실레이터");
plotBaseline1(0, "기준선1");
4,
Input : Period1(5), Period2(20), Period3(60), Period4(120), Period5(200);
var : sumGap(0,data2), gap(0,data2), GC(0,data2);
if date!=date[1] then {
gap = data2(Open-Close[1]);
sumGap = sumGap+gap;
}
GC = C - sumGap;
Plot1(ma(GC,Period1), "단순이동평균1");
Plot2(ma(GC,Period2), "단순이동평균2");
Plot3(ma(GC,Period3), "단순이동평균3");
Plot4(ma(GC,Period4), "단순이동평균4");
Plot5(ma(GC,Period5), "단순이동평균5");
Plot11(wma(GC,Period1), "가중이동평균1");
Plot12(wma(GC,Period2), "가중이동평균2");
Plot13(wma(GC,Period3), "가중이동평균3");
Plot14(wma(GC,Period4), "가중이동평균4");
Plot15(wma(GC,Period5), "가중이동평균5");
Plot21(ema(GC,Period1), "지수이동평균1");
Plot22(ema(GC,Period2), "지수이동평균2");
Plot23(ema(GC,Period3), "지수이동평균3");
Plot24(ema(GC,Period4), "지수이동평균4");
Plot25(ema(GC,Period5), "지수이동평균5");
즐거운 하루되세요
> 뉴스타트 님이 쓴 글입니다.
> 제목 : 문의드립니다.
> 1. 3가지부탁드립니다.
갭보정 Slow 스톡
data2갭보정 Slow 스톡
data2갭보정 MACD 오실레이터(기준선위 빨강,아래 파랑)
2. 일반차트에서 갭보정이평이 필요하네요.
(입력변수는 5,20,60,120,240)
갭보정단순이평
갭보정가중이평
갭보정지수이평
각각 부탁드립니다.
수고하세요.
다음글
이전글