커뮤니티
24488 볼린저 밴드 질문 관련
2012-05-11 11:04:01
290
글번호 50939
하이에서는 고가+종가+저가 로 되어있습니다...
그러면 예스에서도 가격부분을 하이처럼해서 볼린저 밴드를 구할수 있나요?
그리고 분붕에서(Data1) 분봉 가격 Data를 반영한 일봉(Data2)의 볼린저밴드 값을 구할수잇나요?
감사합니다.
답변 1
예스스탁 예스스탁 답변
2012-05-11 11:11:45
안녕하세요
예스스탁입니다.
1.
(고가+종가+저가)/3을 사용하시면 식을 아래와 같습니다.
Input : Period(20), Dv(2);
var : BBup(0),BBmd(0),BBdn(0);
var1 = (H+C+L)/3;
BBmd = ma(var1,Period);
BBup = ma(var1,Period)+Std(var1,Period)*dv;
BBdn = ma(var1,Period)-Std(var1,Period)*dv;
Plot1(BBup, "이평");
Plot2(BBmd, "상단밴드");
Plot3(BBdn, "하단밴드");
2.
분봉에서 일봉의 볼린져밴드를 계산하는 식입니다.
# 분봉에서 일봉 볼린져밴드 계산 시작
input : dayPeriod(30),dayDv(2);
var : daysum(0),daycnt(0),dayma(0),daySumSqrt(0),dayStdv(0);
var : dayBBup(0),dayBBdn(0),dayCounter(0);
daysum = 0;
for daycnt = 0 to dayPeriod-1{
daysum = daysum + (DayHigh(daycnt)+daylow(daycnt)+dayclose(daycnt))/3;
}
dayma = daysum/dayPeriod;
If DayClose(dayPeriod) != 0 Then {
daySumSqrt = 0;
For dayCounter = 0 To dayPeriod - 1 {
daySumSqrt = daySumSqrt + ((DayHigh(dayCounter)+daylow(dayCounter)+dayclose(dayCounter))/3 - dayma)
* ((DayHigh(dayCounter)+daylow(dayCounter)+dayclose(dayCounter))/3 - dayma);
}
dayStdv = SquareRoot(daySumSqrt / dayPeriod);
}
Else
dayStdv = 0;
dayBBup = dayma + (dayDv * dayStdv);
dayBBdn = dayma - (dayDv * dayStdv);
# 분봉에서 일봉 볼린져밴드 계산 끝
plot1(dayBBup);
plot2(dayma );
plot3(dayBBdn);
즐거운 하루되세요
> 대가들의매매 님이 쓴 글입니다.
> 제목 : 24488 볼린저 밴드 질문 관련
> 하이에서는 고가+종가+저가 로 되어있습니다...
그러면 예스에서도 가격부분을 하이처럼해서 볼린저 밴드를 구할수 있나요?
그리고 분붕에서(Data1) 분봉 가격 Data를 반영한 일봉(Data2)의 볼린저밴드 값을 구할수잇나요?
감사합니다.