커뮤니티
부탁 드립니다.
2012-07-31 01:21:13
225
글번호 53365
2분봉 매매입니다.
5일선/20일선(실시간 계산) 정배열, 20일선이 상향추세,
당일 주가가 기준선(26)과 5일선 위에 있으며,
전일 음봉이었고,
당일 14:46분 현재 주가와 5일선과의 이격이 3% 이내,
전일 음봉의 저가와 당일 14:46분 주가와의 이격이 10% 이내,
전일 거래량 보다 당일 거래량이 크며,
당일 14:46분 현재 당일 양봉이며,
현재 주가가 전일의 음봉 시가보다 크면 매수
매수청산 :
매수한 일자의 당일 저가와 매수 전일 음봉 저가중의 작은값을 이탈시에 매도함
샹틀리에 청산: ATR(20)*3 => 일봉 ATR로 실시간 계산 부탁드립니다.
감사합니다.
답변 1
예스스탁 예스스탁 답변
2012-07-31 11:40:59
안녕하세요
예스스탁입니다.
input : P1(5),P2(20);
var : count(0),sumV1(0),sumV2(0),sumV3(0);
var : mav1(0),mav2(0),mav3(0);
input : ATRP(20);
var : TH(0),TL(0),Sum(0),TR(0),DayATR(0),cnt(0);
sumV1 = 0;
sumV2 = 0;
sumV3 = 0;
for count = 0 to P2{
if count < P1 Then
sumV1 = sumV1+DayClose(count);
if count < P2 Then{
sumV2 = sumV2+DayClose(count);
sumV3 = sumV3+DayClose(count+1);
}
}
maV1 = sumV1 / P1;
maV2 = sumV2 / P2;
maV3 = sumV3 / P2;
sum = 0;
for cnt = 0 to ATRP-1{
If DayClose(cnt+1) > dayhigh(cnt) then
TH = DayClose(cnt+1);
else
TH = dayhigh(cnt);
If DayClose(cnt+1) < DayLow(cnt) then
TL = DayClose(cnt+1);
else
TL = daylow(cnt);
TR = TH-TL;
Sum = Sum+TR;
}
DayATR = Sum/ATRP;
if mav1 > mav2 and
mav2 > mav3 and
C > mav1 and
C > (highest(H,26)+lowest(L,26))/2 and
DayClose(1) < dayopen(1) and
stime == 144600 and
C/mav1*100 <= 103 and C/mav1*100 >= 97 and
C/daylow(1)*100 <= 110 and C/daylow*100 >= 90 and
DayVolume > DayVolume(1) and
DayClose > dayopen and
C > dayopen(1) Then
buy();
value1 = min(daylow(1),daylow);
if MarketPosition == 1 Then{
exitlong("bx1",AtStop,value1[BarsSinceEntry]);
exitlong("bx2",AtStop,highest(H,BarsSinceEntry)-DayATR*3);
}
즐거운 하루되세요
> 엠제이 님이 쓴 글입니다.
> 제목 : 부탁 드립니다.
> 2분봉 매매입니다.
5일선/20일선(실시간 계산) 정배열, 20일선이 상향추세,
당일 주가가 기준선(26)과 5일선 위에 있으며,
전일 음봉이었고,
당일 14:46분 현재 주가와 5일선과의 이격이 3% 이내,
전일 음봉의 저가와 당일 14:46분 주가와의 이격이 10% 이내,
전일 거래량 보다 당일 거래량이 크며,
당일 14:46분 현재 당일 양봉이며,
현재 주가가 전일의 음봉 시가보다 크면 매수
매수청산 :
매수한 일자의 당일 저가와 매수 전일 음봉 저가중의 작은값을 이탈시에 매도함
샹틀리에 청산: ATR(20)*3 => 일봉 ATR로 실시간 계산 부탁드립니다.
감사합니다.