커뮤니티
일봉이나 분봉에서 주봉의 시가 전고가 전저가를 나타내는식요
2012-09-14 17:04:57
571
글번호 54717
일봉이나 분봉에서 주봉의 시가, 전고가, 전저가를 나타내는지표식요 부탁드립니다
답변 1
예스스탁 예스스탁 답변
2012-09-14 18:47:08
안녕하세요? 예스스탁입니다.
문의하신 내용 답변드립니다.
아래 지표식으로 작성하시면 되는데, 그 아래의 사용자함수가 작성되어 있어야 합니다.
[지표식]
plot1(weekopen(0)); //주봉의 시가
plot2(weekhigh(0)); //주봉의 고가
plot3(weekLow(0)); //주봉의 저가
plot4(weekClose(0)); //주봉의 종가
plot5(weekopen(1)); //전주 주봉의 시가
plot6(weekhigh(1)); //전주 주봉의 고가
plot7(weekLow(1)); //전주 주봉의 저가
plot8(weekClose(1)); //전주 주봉의 종가
[사용자함수 : WeekOpen ]
input:n(numeric);
var:j(0),요일(0);
array:weekO[100](0);
요일 = DayOfWeek(date);
if date[1] < date and 요일[1] >= 요일 then {
for j = 99 downto 1 {
weekO[j] = weekO[j-1];
}
weekO[0] = o;
}
WeekOpen = weekO[n];
[사용자함수 :WeekHigh ]
Input : N(numeric);
var : cnt(0);
array : WH[99](0);
if DayOfWeek(date) < DayOfWeek(date)[1] then{
WH[0] = H;
for cnt = 1 to 20{
WH[cnt] = WH[cnt-1][1];
}
}
if H > WH[0] then{
WH[0] = H;
}
WeekHigh = WH[N];
[사용자함수 :WeekLow ]
Input : N(numeric);
var : cnt(0);
array : WL[99](0);
if DayOfWeek(date) < DayOfWeek(date)[1] then{
WL[0] = L;
for cnt = 1 to 20{
WL[cnt] = WL[cnt-1][1];
}
}
if L < WL[0] then{
WL[0] = L;
}
WeekLow = WL[N];
[사용자함수 : Weekclose ]
input : N(numeric);
var : cnt(0);
array : WC[99](0);
if DayOfWeek(date) < DayOfWeek(date)[1] then{
for cnt = 1 to 98{
WC[cnt] = WC[cnt-1][1];
}
}
WC[0] = C;
Weekclose = WC[N];
즐거운 날 되세요..
> 팔보채 님이 쓴 글입니다.
> 제목 : 일봉이나 분봉에서 주봉의 시가 전고가 전저가를 나타내는식요
> 일봉이나 분봉에서 주봉의 시가, 전고가, 전저가를 나타내는지표식요 부탁드립니다
이전글