커뮤니티
지표 수정해주세요
2012-11-27 11:09:36
466
글번호 56852
첨부파일은 스윙을 이용한 파동선 지표입니다. 가격에 적용해 사용하고 있는데요.
같은 형식으로 RSI에 적용가능하도록 수정하여 사용해보려고 합니다.
RSI에 더하는 방식이 아닌 RSI와 RSI스윙파동선이 함께 나오도록 수정해주세요.
RSI를 변수화하여 MACD나 스토캐스틱으로 바로 바꿔 사용할 수 있도록 만들어 주시면
감사하겠습니다.
- 1. _Swing파동선110303.yin (0.00 MB)
답변 1
예스스탁 예스스탁 답변
2012-11-27 15:42:53
안녕하세요
예스스탁입니다.
value라는 변수에 RSI값을 할당해서
모든 가격데이터를 대체했습니다.
다른 지표로 변경하실때 value에 해당지표의 함수로
대체해 주시면 됩니다. 따로 변수로 처리는 되지 않습니다.
#==========================================#
# 지표명 : Swing파동선
# 작성자 : 수식지왕
# 블로그 : http://yahoosir.blog.me
#==========================================#
Input:left(5),right(5),RSIP(14);
Var:j(0),k(0),이중파동(0),구분(0),고점(100),저점(-100),value(0);
Array:고[20](0),저[20](0),고Bar[20](0),저Bar[20](0);
value = RSI(RSIP);
plot99(value);
#==========================================#
# 전고점,전저점 index 증가
#==========================================#
For j = 1 To 19
{
고Bar[j] = 고Bar[j] + 1;
저Bar[j] = 저Bar[j] + 1;
}
#==========================================#
# 이중파동 처리
#==========================================#
If 이중파동 > 0 Then
{
Plot1(이중파동);
이중파동 = 0;
}
#==========================================#
# 변곡점 정의
#==========================================#
구분 = 0;
If Highest(value,left)[right+1] <= value[right] && value[right] > Highest(value,right) &&
Lowest(value,left)[right+1] >= value[right] && value[right] < Lowest(value,right) Then
{
구분 = Iff(고Bar[1]>저Bar[1],고점,저점);
}
Else If Highest(value,left)[right+1] <= value[right] && value[right] > Highest(value,right) Then
구분 = 고점;
Else If Lowest(value,left)[right+1] >= value[right] && value[right] < Lowest(value,right) Then
구분 = 저점;
#==========================================#
# 전고점(Peak) 계산
#==========================================#
If 구분 == 고점 Then
{
For j = 18 DownTo 1
{
고[j+1] = 고[j];
고Bar[j+1] = 고Bar[j];
}
고[1] = value[right];
고Bar[1] = right;
If 저Bar[1] > 고Bar[2] Then
{
For j = 18 downto 1
{
저[j+1] = 저[j];
저Bar[j+1] = 저Bar[j];
}
k = right + 1;
For j = right + 2 To 고Bar[2]-1
{
If value[k] > value[j] Then k = j;
}
저[1] = value[k];
저Bar[1] = k;
Plot1(저[1]);
이중파동 = 고[1];
}
If 이중파동 == 0 Then Plot1(고[1]);
}
#==========================================#
# 전저점(Trough) 계산
#==========================================#
If 구분 == 저점 Then
{
For j = 18 DownTo 1
{
저[j+1] = 저[j];
저Bar[j+1] = 저Bar[j];
}
저[1] = value[right];
저Bar[1] = right;
If 고Bar[1] > 저Bar[2] Then
{
For j = 18 DownTo 1
{
고[j+1] = 고[j];
고Bar[j+1] = 고Bar[j];
}
k = right + 1;
For j = right + 2 To 저Bar[2]-1
{
If value[k] < value[j] Then k = j;
}
고[1] = value[k];
고Bar[1] = k;
Plot1(고[1]);
이중파동 = 저[1];
}
If 이중파동 == 0 Then Plot1(저[1]);
}
#==========================================#
# 마무리
#==========================================#
If LastBarOnChart == 1 && 고Bar[1] != right && 저Bar[1] != right Then
{
If 고Bar[1] > 저Bar[1] Then plot1(Highest(value,저Bar[1]));
Else plot1(Lowest(value,고Bar[1]));
}
즐거운 하루되세요
> 하얀마음흑구 님이 쓴 글입니다.
> 제목 : 지표 수정해주세요
> 첨부파일은 스윙을 이용한 파동선 지표입니다. 가격에 적용해 사용하고 있는데요.
같은 형식으로 RSI에 적용가능하도록 수정하여 사용해보려고 합니다.
RSI에 더하는 방식이 아닌 RSI와 RSI스윙파동선이 함께 나오도록 수정해주세요.
RSI를 변수화하여 MACD나 스토캐스틱으로 바로 바꿔 사용할 수 있도록 만들어 주시면
감사하겠습니다.
다음글
이전글