커뮤니티
수식 부탁드립니다.
2013-09-03 17:38:59
92
글번호 67151
1. 일봉에서 주봉 볼린져밴드를 실시간으로 보는 지표식
2. 일봉에서 월봉 볼린져밴드를 실시간으로 보는 지표식
3. 분봉에서 일봉 볼린져밴드를 실시간으로 보는 지표식
4. 분봉에서 주봉 볼린져밴드를 실시간으로 보는 지표식
답변 1
예스스탁 예스스탁 답변
2013-09-04 13:31:33
안녕하세요
예스스탁입니다.
1번과 4번은 같은 식은 같습니다.
분봉에서 주봉 볼린져밴드를 계산할 만큼 기간이 되지 않을수 있으므로
유의하시기 바립니다.
1. 일봉이하에서 주봉 볼린져밴드
input : weekPeriod(20),weekDv(2);
var : weekcnt(0),weekcount(0),weeksum(0),weekmav(0),weekBBup(0),weekBBdn(0),weekSumSqrt(0),weekCounter(0),weekStdv(0);
Array : weekC[120](0);
if dayofweek(date) < dayofweek(date[1]) Then{
for weekcnt = 1 to weekPeriod+1{
weekC[weekcnt] = weekC[weekcnt-1][1];
}
}
weekC[0] = C;
If weekC[weekPeriod] != 0 Then {
weeksum = 0;
for weekcount = 0 to weekPeriod-1{
weeksum = weeksum+weekC[weekcount];
}
weekmav = weeksum/weekPeriod;
weekSumSqrt = 0;
For weekCounter = 0 To weekPeriod - 1 {
weekSumSqrt = weekSumSqrt + (weekC[weekCounter] - weekmav) * (weekC[weekCounter] - weekmav);
}
weekStdv = SquareRoot(weekSumSqrt / weekPeriod);
weekBBup = weekmav + (weekDv * weekStdv);
weekBBdn = weekmav - (weekDv * weekStdv);
plot1(weekBBup);
plot2(weekmav );
plot3(weekBBdn);
}
2.일봉이하에서 월봉 볼린져밴드
input : MonthPeriod(10),MonthDv(2);
var : Monthcnt(0),Monthcount(0),Monthsum(0),Monthmav(0),MonthBBup(0),MonthBBdn(0),MonthAvgv(0),MonthSumSqrt(0),MonthCounter(0),MonthStdv(0);
Array : MonthC[120](0);
if date > date[1]+30 Then{
MonthC[1] = C[1];
for Monthcnt = 2 to MonthPeriod+1{
MonthC[Monthcnt] = MonthC[Monthcnt-1][1];
}
Monthsum = 0;
for Monthcount = 1 to MonthPeriod-1{
Monthsum = Monthsum+MonthC[Monthcount];
}
}
MonthC[0] = C;
Monthmav = (C+Monthsum)/MonthPeriod;
If MonthC[MonthPeriod] != 0 Then Begin
MonthAvgv = Monthmav;
MonthSumSqrt = 0;
For MonthCounter = 0 To MonthPeriod - 1 Begin
MonthSumSqrt = MonthSumSqrt + (MonthC[MonthCounter] - MonthAvgv) * (MonthC[MonthCounter] - MonthAvgv);
End;
MonthStdv = SquareRoot(MonthSumSqrt / MonthPeriod);
End
Else
MonthStdv = 0;
MonthBBup = Monthmav + (MonthDv * MonthStdv);
MonthBBdn = Monthmav - (MonthDv * MonthStdv);
# 분봉에서 월봉 볼린져밴드 계산 끝
plot1(MonthBBup);
plot2(Monthmav );
plot3(MonthBBdn);
3. 분봉이하에서 일봉 볼린져밴드
input : dayPeriod(20),dayDv(2);
var : daysum(0),daycnt(0),dayma(0),daySumSqrt(0),dayStdv(0);
var : dayBBup(0),dayBBdn(0),dayCounter(0);
#일봉 이동평균 계산
daysum = 0;
for daycnt = 0 to dayPeriod-1{
daysum = daysum + DayClose(daycnt);
}
dayma = daysum/dayPeriod;
#표준편차 계산
If DayClose(dayPeriod) != 0 Then {
daySumSqrt = 0;
For dayCounter = 0 To dayPeriod - 1 {
daySumSqrt = daySumSqrt + (DayClose(dayCounter) - dayma)^2;
}
dayStdv = SquareRoot(daySumSqrt / dayPeriod);
}
Else
dayStdv = 0;
# 일봉 볼린져밴드 계산
dayBBup = dayma + (dayDv * dayStdv);
dayBBdn = dayma - (dayDv * dayStdv);
plot1(dayBBup ,"상단");
plot2(dayma,"중단");
plot3(dayBBdn,"하단");
즐거운 하루되세요
> 엠제이 님이 쓴 글입니다.
> 제목 : 수식 부탁드립니다.
> 1. 일봉에서 주봉 볼린져밴드를 실시간으로 보는 지표식
2. 일봉에서 월봉 볼린져밴드를 실시간으로 보는 지표식
3. 분봉에서 일봉 볼린져밴드를 실시간으로 보는 지표식
4. 분봉에서 주봉 볼린져밴드를 실시간으로 보는 지표식
다음글
이전글