커뮤니티
수식부탁드립니다
2013-09-25 16:55:36
153
글번호 67818
첨부 이미지
그림1
선물 5분봉상 120이평을 5분봉이 돌파할때 120이평값을 체크해주거나
120이평에 5분봉이 0.2포인트 가까워졌을때 체크해줍니다. 그다음,
체크한 120이평으로부터 50분이내 1.2포인트이상 떨어지거나 올랐을때
체크해주는 방식입니다.
차트 확인해보시면,
1. 5분봉이 120이평선을 하향이탈할때 120평선의 값을 수평선이나 혹은수치 강조식등 눈에볼수있게 표현합니다.
2. 체크한 120평선값으로부터 50분내에(10봉) 1.2포인트이상 빠지면 그림처럼 선이나 수치 강조식등으로 표현해주는겁니다.
가능할까요?
- 1. 체크.JPG (0.03 MB)
답변 1
예스스탁 예스스탁 답변
2013-09-26 11:45:26
안녕하세요
예스스탁입니다.
문의하신 내용은 추세선 함수로 구현되어야 합니다.
아래식 검색식으로 작성하신후 차트에 적용하시면
120이평을 상향이나 하향이탈한 봉에 점으로 표시하고
50분이내에 1.2를 이탈하면 그때부터 선으로 그려집니다.
가장 최근것만 표시됩니다.
input : Pt(1.2);
var : TL1(0),TL2(0),Trend(0),DD(0),TT(0),mav(0),TM(0);
var1 = ma(c,120);
if Crossup(c,var1) Then{
Trend = 1;
TM = TimeToMinutes(stime);
mav = var1;
DD = sdate;
TT = stime;
plot1(mav,"이평하향이탈",MAGENTA);
}
if CrossDown(c,var1) Then{
Trend = -1;
TM = TimeToMinutes(stime);
mav = var1;
DD = sdate;
TT = stime;
plot1(mav,"이평하향이탈",CYAN);
}
if Trend == 1 and sdate == DD then{
if TimeToMinutes(stime) < TM+50 and TimeToMinutes(stime) > TM and H >= mav+Pt Then
Trend = 2;
}
if Trend == 2 Then{
TL_Delete(TL1);
TL_Delete(TL2);
TL1 = TL_New(DD,TT,mav,sdate,stime,mav);
TL2 = TL_New(DD,TT,mav+Pt,sdate,stime,mav+Pt);
}
if Trend == -1 and sdate == DD then{
if TimeToMinutes(stime) < TM+50 and TimeToMinutes(stime) > TM and L <= mav-Pt Then
Trend = -2;
}
if Trend == -2 Then{
TL_Delete(TL1);
TL_Delete(TL2);
TL1 = TL_New(DD,TT,mav,sdate,stime,mav);
TL2 = TL_New(DD,TT,mav-Pt,sdate,stime,mav-Pt);
}
즐거운 하루되세요
> 드림컴트루1 님이 쓴 글입니다.
> 제목 : 수식부탁드립니다
> 선물 5분봉상 120이평을 5분봉이 돌파할때 120이평값을 체크해주거나
120이평에 5분봉이 0.2포인트 가까워졌을때 체크해줍니다. 그다음,
체크한 120이평으로부터 50분이내 1.2포인트이상 떨어지거나 올랐을때
체크해주는 방식입니다.
차트 확인해보시면,
1. 5분봉이 120이평선을 하향이탈할때 120평선의 값을 수평선이나 혹은수치 강조식등 눈에볼수있게 표현합니다.
2. 체크한 120평선값으로부터 50분내에(10봉) 1.2포인트이상 빠지면 그림처럼 선이나 수치 강조식등으로 표현해주는겁니다.
가능할까요?