커뮤니티
부탁합니다.
2013-10-16 11:07:22
169
글번호 68513
수고 많습니다.
일봉 5이평,주봉 5이평선이 상승이면서 30분봉 스톡D(5,3,3)이 침체(20)이면
3분봉 스톡k가 50선 상향돌파면 매수,,반대면 매도하는 식을 구사해 주시기 바랍니다
첨언)3분봉차트로 구현하려 함
감사합니다.
답변 1
예스스탁 예스스탁 답변
2013-10-16 15:33:43
안녕하세요
예스스탁입니다.
수식의 내용은 아래와 같습니다.
차트의 최대 조회갯수가 5000입니다.
3분 차트시면 주봉으로는 약 거래일로 9주정도의 데이터입니다.
최대인 5000개봉으로 차트를 조회하시고 적용하시기 바랍니다.
input : P(5),Atime(30),StoPeriod(10), StoPeriod1(6), StoPeriod2(6);
var : count(0),Dsum1(0),Dsum2(0),Dmav1(0),Dmav2(0);
var : Wsum1(0),Wsum2(0),Wmav1(0),Wmav2(0);
var : highVal(0), lowVal(0), StoFastK(0), StoK(0), StoD(0),SK(0);
var : Ep(0), EP1(0), JISU(0), DINDEX(0), PreStoK(0), PreStoD(0),cnt(0);
Array : HH[50](0),LL[50](0),WeekC[100](0);
#일봉이평 계산
Dsum1 = 0;
DSum2 = 0;
for count = 0 to P-1{
Dsum1 = Dsum1+DayClose(count);
Dsum2 = Dsum2+DayClose(count+1);
}
DmaV1 = Dsum1 / P;#당일 일봉 5이평
DmaV2 = Dsum2 / P;#전일 일봉 5이평
#일봉이평 계산 끝
#주봉이평 계산
if DayOfWeek(Sdate) < DayOfWeek(sdate[1]) Then{
for count = 1 to 99{
WeekC[count] = WeekC[count-1][1];
}
}
WeekC[0] = C;
Wsum1 = 0;
Wsum2 = 0;
for count = 0 to P-1{
Wsum1 = Wsum1+WeekC[count];
Wsum2 = Wsum2+WeekC[count+1];
}
Wmav1 = Wsum1/P;
Wmav2 = Wsum2/P;
#주봉이평 계산 끝
#30분봉 스토케스틱 계산
var1 = TimeToMinutes(stime)%Atime;
if dayindex == 0 or (var1 < var1[1] and stime > stime[1]) Then{
HH[0] = H;
LL[0] = L;
for cnt = 1 to 49{
HH[cnt] = HH[cnt-1][1];
LL[cnt] = LL[cnt-1][1];
}
}
if H > HH[0] Then
HH[0] = H;
if L < LL[0] Then
LL[0] = L;
highVal = HH[0];
lowVal = LL[0];
for count = 0 to StoPeriod-1 {
if HH[count] > highVal then
highVal = HH[count];
if LL[count] < lowVal then
lowVal = LL[count];
}
StoFastK = (C-lowVal)/(highVal-lowVal)*100;
#### Slow StochasticsK ####
Ep = 2/(StoPeriod1+1);
if DINDEX >= StoPeriod and (date != date[1] or var1 < var1[1]) then {
DINDEX = DINDEX + 1;
PreStoK = StoK[1];
}
if DINDEX <= 1 then
StoK = StoFastK ;
else
StoK = StoFastK * EP + PreStoK * (1-EP);
#### Slow StochasticsD ####
Ep1 = 2/(StoPeriod2+1);
if date != date[1] or var1 < var1[1] then {
DINDEX = DINDEX + 1;
PreStoD = StoD[1];
}
if DINDEX <= 1 then
StoD = StoK ;
else
StoD = StoK * EP1 + PreStoD * (1-EP1);
Sk = StochasticsK(stoPeriod,StoPeriod1);
if Dmav2 > 0 and Wmav2 > 0 and
Dmav1 > Dmav2 and Wmav1 > Wmav2 and StoD <= 20 and crossup(SK,50) Then
buy();
if Dmav2 > 0 and Wmav2 > 0 and
Dmav1 < Dmav2 and Wmav1 < Wmav2 and StoD >= 80 and CrossDown(SK,50) Then
sell();
즐거운 하루되세요
> 먼지의추억 님이 쓴 글입니다.
> 제목 : 부탁합니다.
> 수고 많습니다.
일봉 5이평,주봉 5이평선이 상승이면서 30분봉 스톡D(5,3,3)이 침체(20)이면
3분봉 스톡k가 50선 상향돌파면 매수,,반대면 매도하는 식을 구사해 주시기 바랍니다
첨언)3분봉차트로 구현하려 함
감사합니다.