커뮤니티
수고하십니다. 시스템식 부탁드립니다.
2013-10-18 10:55:57
150
글번호 68604
주식이구요...
장시작후 30분 안에서만 매수하고 싶은데요...
전일종가대비 +3% (12만원), +4%(12만원),+5%(12만원) 스탑매수 3분할...
로 매수 하고 싶구요
손절은: 매수진입후 전일종가대비 0.5% 저점만들면 손절바로 들어가고 싶습니다.
이익실현은: 일단 당일상한가에 걸어놓고 싶구요...
11시 이전에 상한가를 들어가지 못하면...
당일 최고가를 만든 가격의 -1틱(또는 -1호가) 익절 걸어 놓고 싶습니다.
감사합니다. 부탁드립니다.
답변 1
예스스탁 예스스탁 답변
2013-10-18 12:43:09
안녕하세요
예스스탁입니다.
input : 투자금액1(12000),투자금액2(12000),투자금액3(12000);
var : Vol1(0),vol2(0),vol3(0);
var : 상한가(0), UpLimit(0);
var : up1(0), up2(0), up3(0), up4(0), up5(0),up6(0);
if date >= 19981207 then {
if date < 20050328 && CodeCategory() == 2 then
UpLimit = (BP[0] * 1.12);
Else
UpLimit = (BP[0] * 1.15);
if CodeCategory() == 2 then {
if date >= 20030721 then {
up1 = int(UpLimit/100+0.00001)*100;
up2 = int(UpLimit/100+0.00001)*100;
up3 = int(UpLimit/100+0.00001)*100;
up4 = int(UpLimit/50+0.00001)*50;
up5 = int(UpLimit/10+0.00001)*10;
up6 = int(UpLimit/5+0.00001)*5;
}
else {
up1 = int(UpLimit/1000+0.00001)*1000;
up2 = int(UpLimit/500+0.00001)*500;
up3 = int(UpLimit/100+0.00001)*100;
up4 = int(UpLimit/50+0.00001)*50;
up5 = int(UpLimit/10+0.00001)*10;
up6 = int(UpLimit/10+0.00001)*10;
}
}
Else {
up1 = int(UpLimit/1000+0.00001)*1000;
up2 = int(UpLimit/500+0.00001)*500;
up3 = int(UpLimit/100+0.00001)*100;
up4 = int(UpLimit/50+0.00001)*50;
up5 = int(UpLimit/10+0.00001)*10;
up6 = int(UpLimit/5+0.00001)*5;
}
if CodeCategory() == 1 || CodeCategory() == 2 then {
If BP >= 500000 Then
상한가 = up1;
Else If BP >= 100000 Then
상한가 = iff(up2>=500000, up1, up2);
Else If BP >= 50000 Then
상한가 = iff(up3>=100000, up2, up3);
Else If BP >= 10000 Then
상한가 = iff(up4>=50000, up3, up4);
Else If BP >= 5000 Then
상한가 = iff(up5>=10000, up4, up5);
Else
상한가 = iff(up6>=5000, up5, up6);
}
else if CodeCategory() == 8 || CodeCategory() == 9 then { // ETF
상한가 = up6;
}
}
if CodeCategoryEx == 11 and BasePrice < 50000 Then{
vol1 = int(int((투자금액1)/C)/10)*10;
vol2 = int(int((투자금액2)/C)/10)*10;
vol3 = int(int((투자금액3)/C)/10)*10;
}
Else{
vol1 = int((투자금액1)/C);
vol2 = int((투자금액2)/C);
vol3 = int((투자금액3)/C);
}
if stime == 150000 Then{
buy("b1",AtStop,C*1.03,vol1);
buy("b2",AtStop,C*1.04,vol2);
buy("b3",AtStop,C*1.05,vol3);
}
if stime < 93000 and CurrentEntries < 3 then{
if DayHigh < DayClose(1)*1.03 Then
buy("b11",AtStop,DayClose(1)*1.03,vol1);
if DayHigh < DayClose(1)*1.04 Then
buy("b21",AtStop,DayClose(1)*1.04,vol2);
if DayHigh < DayClose(1)*1.05 Then
buy("b31",AtStop,DayClose(1)*1.05,vol3);
}
if MarketPosition == 1 Then{
exitlong("bx",AtStop,DayClose(1)*0.995);
if stime < 110000 Then
ExitLong("bx2",Atlimit,상한가);
if stime >= 110000 Then{
if H < dayhigh Then
ExitLong("bx3",atlimit,dayhigh-PriceScale*1);
if H == dayhigh Then
ExitLong("bx4",AtStop,dayhigh-PriceScale*1);
}
}
즐거운 하루되세요
> 신나는파파 님이 쓴 글입니다.
> 제목 : 수고하십니다. 시스템식 부탁드립니다.
>
주식이구요...
장시작후 30분 안에서만 매수하고 싶은데요...
전일종가대비 +3% (12만원), +4%(12만원),+5%(12만원) 스탑매수 3분할...
로 매수 하고 싶구요
손절은: 매수진입후 전일종가대비 0.5% 저점만들면 손절바로 들어가고 싶습니다.
이익실현은: 일단 당일상한가에 걸어놓고 싶구요...
11시 이전에 상한가를 들어가지 못하면...
당일 최고가를 만든 가격의 -1틱(또는 -1호가) 익절 걸어 놓고 싶습니다.
감사합니다. 부탁드립니다.