커뮤니티
문의 드립니다.
2013-11-19 21:54:02
166
글번호 69629
수고 많으십니다.
두 가지 수식이 궁금합니다.
macd와 스토캐스틱 지표의 시작을 당일의 첫봉부터 계산하는 수식을 알려주세요.
갭보정 지표 말구요.
지표를 넣으면 지표의 기간값에 따라 일정갯수의 봉들이 지나간 후에 계산된 지표가 표시되지 않습니까?
전날 계산된 지표값을 초기화시키고 당일분의 지표만 넣어서 시스템식을 바꿔보고 싶습니다.
어제 마지막 봉의 지표값을 불러오는 수식이 있는지 궁금합니다. macd와 스토캐스틱 등의 마지막 지표값을 불러오는 수식을 알려주세요.
답변 1
예스스탁 예스스탁 답변
2013-11-20 13:55:24
안녕하세요
예스스탁입니다.
1.
Input : Period1(12),Period2(26);
Var : Ep1(0),EP2(0),EP3(0),JISU1(0),JISU2(0),MACDV(0),MACDS(0);
Ep1 = 2/(Period1+1);
Ep2 = 2/(Period2+1);
Ep3 = 2/(Period2+1);
if dayindex == 0 then{
JISU1 = C;
JISU2 = C;
MACDV = Jisu1-jisu2;
MACDS = MACDV;
var1 = MACDV[1];
var2 = MACDS[1];
}
else{
JISU1 = C * EP1 + JISU1[1] * (1-EP1);
JISU2 = C * EP2 + JISU2[1] * (1-EP2);
MACDV = Jisu1-jisu2;
MACDS = MACDV * EP3 + MACDS[1] * (1-EP3);
}
plot1(MACDV,"MACDV");
plot2(MACDS,"MACDsignal");
plot3(var1,"전일마지막봉MACDV");
plot4(var2,"전일마지막봉MACDsignal");
PlotBaseLine1(0);
2.
Input : Period1(10),Period2(5),Period3(5);
Var : HH(0),LL(0),FK(0),EP1(0),EP2(0),SK(0),SD(0);
if dayindex < Period1 Then{
HH = DayHigh;
LL = DayLow;
}
Else{
HH = highest(H,Period1);
LL = lowest(L,Period1);
}
FK = (Close - LL) / (HH - LL) * 100;
EP1 = 2/(Period2+1);
EP2 = 2/(Period3+1);
if dayindex == 0 Then{
SK = FK;
SD = SK;
var1 = Sk[1];
var2 = SD[1];
}
Else{
SK = FK * EP1 + SK[1] * (1-EP1);
SD = SK * EP2 + SD[1] * (1-EP2);
}
plot1(SK,"%k");
plot2(SD,"%D");
plot3(var1,"전일마지막봉 %k");
plot4(var2,"전일마지막봉 %D");
PlotBaseLine1(20);
PlotBaseLine2(80);
3.
위 수식에 전일마지막봉 값도 그리게 작성되어 있습니다.
참고하시기 바랍니다.
즐거운 하루되세요
> 서쪽하늘 님이 쓴 글입니다.
> 제목 : 문의 드립니다.
> 수고 많으십니다.
두 가지 수식이 궁금합니다.
macd와 스토캐스틱 지표의 시작을 당일의 첫봉부터 계산하는 수식을 알려주세요.
갭보정 지표 말구요.
지표를 넣으면 지표의 기간값에 따라 일정갯수의 봉들이 지나간 후에 계산된 지표가 표시되지 않습니까?
전날 계산된 지표값을 초기화시키고 당일분의 지표만 넣어서 시스템식을 바꿔보고 싶습니다.
어제 마지막 봉의 지표값을 불러오는 수식이 있는지 궁금합니다. macd와 스토캐스틱 등의 마지막 지표값을 불러오는 수식을 알려주세요.