커뮤니티
안녕하세요(2.4배수골든크로스 동시만족)
2017-08-24 17:26:07
162
글번호 70471
안녕하세요 반갑습니다
세가지 질문을 할까합니다
A) 1.2.3.항 동시만족시 매수 반대면 매도
1.현재분챠트 5>20 정배열 이고
2.현재분챠트의 4배수챠트 5>20 정배열
3.현재분챠트의 16배수챠트 5>20 정배열
B)1.2.항 동시만족시 매수 반대면 매도
1.현재분챠트 5>20 정배열 이고
2.현재분챠트의 4배수챠트 5>20 정배열
C)1.2.항 동시만족시 매수 반대면 매도
1.현재분챠트 5>20 정배열 이고
2.RSI 시그널 돌파
항상고맙고 감사합니다.
답변 1
예스스탁 예스스탁 답변
2013-12-16 12:28:27
안녕하세요
예스스탁입니다.
1.
input : N1(4),N2(16),P1(5),P2(20);
var : mav1(0),mav2(0),T1(0);
var : TF1(0),cnt1(0),count1(0),sum11(0),mav11(0),sum12(0),mav12(0);
var : TF2(0),cnt2(0),count2(0),sum21(0),mav21(0),sum22(0),mav22(0);
Array : CC1[100](0),CC2[100](0);
mav1 = ma(C,P1);
mav2 = ma(C,P2);
if date != date[1] Then
T1 = TimeToMinutes(stime);
TF1 = (TimeToMinutes(stime)-T1)%(BarInterval*N1);
if dayindex() == 0 or (TF1 < TF1[1] and stime > stime[1]) Then{
for cnt1 = 1 to 99{
CC1[cnt1] = CC1[cnt1-1][1];
}
}
CC1[0] = C;
if CC1[P2] > 0 then{
sum11 = 0;
sum12 = 0;
for count1 = 0 to P2{
if count1 < P1 Then
sum11 = sum11+CC1[count1];
if count1 < P2 Then
sum12 = sum12+CC1[count1];
}
mav11 = sum11/P1;
mav12 = sum12/P2;
}
TF2 = (TimeToMinutes(stime)-T1)%(BarInterval*N2);
if dayindex() == 0 or (TF2 < TF2[1] and stime > stime[1]) Then{
for cnt2 = 1 to 99{
CC2[cnt2] = CC2[cnt2-1][1];
}
}
CC2[0] = C;
if CC2[P2] > 0 then{
sum21 = 0;
sum22 = 0;
for count2 = 0 to P2{
if count2 < P1 Then
sum21 = sum21+CC2[count2];
if count2 < P2 Then
sum22 = sum22+CC2[count2];
}
mav21 = sum21/P1;
mav22 = sum22/P2;
}
if mav1 > mav2 and
mav11 > mav12 and mav12 > 0 and
mav21 > mav22 and mav21 > 0 Then
buy();
if mav1 < mav2 and
mav11 < mav12 and mav12 > 0 and
mav21 < mav22 and mav21 > 0 Then
sell();
2.
input : N1(4),P1(5),P2(20);
var : mav1(0),mav2(0),T1(0);
var : TF1(0),cnt1(0),count1(0),sum11(0),mav11(0),sum12(0),mav12(0);
Array : CC1[100](0);
mav1 = ma(C,P1);
mav2 = ma(C,P2);
if date != date[1] Then
T1 = TimeToMinutes(stime);
TF1 = (TimeToMinutes(stime)-T1)%(BarInterval*N1);
if dayindex() == 0 or (TF1 < TF1[1] and stime > stime[1]) Then{
for cnt1 = 1 to 99{
CC1[cnt1] = CC1[cnt1-1][1];
}
}
CC1[0] = C;
if CC1[P2] > 0 then{
sum11 = 0;
sum12 = 0;
for count1 = 0 to P2{
if count1 < P1 Then
sum11 = sum11+CC1[count1];
if count1 < P2 Then
sum12 = sum12+CC1[count1];
}
mav11 = sum11/P1;
mav12 = sum12/P2;
}
if mav1 > mav2 and
mav11 > mav12 and mav12 > 0 Then
buy();
if mav1 < mav2 and
mav11 < mav12 and mav12 > 0 Then
sell();
3.
input : P1(5),P2(20),Period(14),sig(10);
var : mav1(0),mav2(0), RSiv(0),RSIs(0);
mav1 = ma(C,P1);
mav2 = ma(C,P2);
RSIv = RSI(Period);
RSIs = ma(RSIV,Sig);
if mav1 > mav2 and crossup(RSIv,RSIs) Then
buy();
if mav1 < mav2 and CrossDown(RSIv,RSIs) Then
sell();
즐거운 하루되세요
> jbouu123 님이 쓴 글입니다.
> 제목 : 안녕하세요
> 안녕하세요 반갑습니다
세가지 질문을 할까합니다
A) 1.2.3.항 동시만족시 매수 반대면 매도
1.현재분챠트 5>20 정배열 이고
2.현재분챠트의 4배수챠트 5>20 정배열
3.현재분챠트의 16배수챠트 5>20 정배열
B)1.2.항 동시만족시 매수 반대면 매도
1.현재분챠트 5>20 정배열 이고
2.현재분챠트의 4배수챠트 5>20 정배열
C)1.2.항 동시만족시 매수 반대면 매도
1.현재분챠트 5>20 정배열 이고
2.RSI 시그널 돌파
항상고맙고 감사합니다.
다음글
이전글