커뮤니티
수식 부탁
2014-01-29 23:49:18
155
글번호 72026
분봉에서 추세선 (상승추세 또는 하락추세)을 그어놓고
주가가 추세선 돌파 또는 이탈하면 매수 또는 매도 하는 시스템식 가능한지요
시스템식 부탁합니다
답변 1
예스스탁 예스스탁 답변
2014-02-03 11:42:33
안녕하세요
예스스탁입니다.
보조도구로 직접 차트에 그리신 추세선을 이용해서는
신호를 발생할 수 없습니다.
수식안에서 추세선 함수를 이용해 추세선을 만드신 다음
신호가 발생하게 하셔야 합니다.
아래식 참고하시기 바랍니다.
input : Left(3),Right(3);
var : HV(0),HD(0),HT(0),preHV(0),preHD(0),preHT(0);
var : LV(0),LD(0),LT(0),preLV(0),preLD(0),preLT(0);
if SwingHigh(1,H,left,Right,Left+right+1) != -1 Then{
HV = H[right];
HT = stime[right];
HD = sdate[right];
PreHV = HV[1];
preHT = HT[1];
preHD = HD[1];
if Hv > PreHv and preHV > 0 Then{
TL_Delete(value1);
value1 = TL_New(preHD,preHT,preHV,HD,HT,HV);
}
TL_SetExtRight(value1,true);
TL_SetColor(value1,RED);
}
if SwingLow(1,L,left,Right,Left+right+1) != -1 Then{
LV = L[right];
LT = stime[right];
LD = sdate[right];
PreLV = LV[1];
preLT = LT[1];
preLD = LD[1];
if Lv < PreLv and preLV > 0 Then{
TL_Delete(value2);
value2 = TL_New(preLD,preLT,preLV,LD,LT,LV);
}
TL_SetExtRight(value2,true);
TL_SetColor(value2,blue);
}
if c > TL_GetValue(value1,sdate,stime) and C[1] < TL_GetValue(value1,sdate[1],stime[1]) Then
buy();
if c < TL_GetValue(value2,sdate,stime) and C[1] > TL_GetValue(value2,sdate[1],stime[1]) Then
sell();
즐거운 하루되세요
> 미래테크 님이 쓴 글입니다.
> 제목 : 수식 부탁
> 분봉에서 추세선 (상승추세 또는 하락추세)을 그어놓고
주가가 추세선 돌파 또는 이탈하면 매수 또는 매도 하는 시스템식 가능한지요
시스템식 부탁합니다