커뮤니티
문의드립니다.
2014-03-04 09:20:52
131
글번호 73160
안녕하세요,,,
예전에 RSI일봉지표를 분봉에서 볼 수 있게 제작해주셨는데요,,,
죄송한데,,,
Data2 로 적용할수 있게 제작해주시면 감사하겠습니다.
늘 감사드립니다.
답변 1
예스스탁 예스스탁 답변
2014-03-04 15:21:17
안녕하세요
예스스탁입니다.
Inputs: Length(9);
Var : cnt(0,data2),Counter(0,data2), DownAmt(0,data2), UpAmt(0,data2), UpSum(0,data2), DownSum(0,data2), UpAvg(0,data2), DownAvg(0,data2);
var : RSIv(0,data2),didx(0,data2), UpAvg1(0,data2), DownAvg1(0,data2);
Array : CC[50](0);
if data2(date != date[1]) Then{
didx = didx+1;
UpAvg1 = UpAvg[1];
DownAvg1 = DownAvg[1];
for cnt = 1 to 49{
CC[cnt] = CC[cnt-1][1];
}
}
CC[0] = data2(C);
If didx <= 1 AND Length > 0 Then Begin
UpSum = 0;
DownSum = 0;
For Counter = 0 To Length - 1 Begin
UpAmt = CC[Counter] - CC[Counter+1];
If UpAmt >= 0 Then
DownAmt = 0;
Else Begin
DownAmt = -UpAmt;
UpAmt = 0;
End;
UpSum = UpSum + UpAmt;
DownSum = DownSum + DownAmt;
End;
UpAvg = UpSum / Length;
DownAvg = DownSum / Length;
End
Else If didx > 1 AND Length > 0 Then Begin
UpAmt = CC[0] - CC[1];
If UpAmt >= 0 Then
DownAmt = 0;
Else Begin
DownAmt = -UpAmt;
UpAmt = 0;
End;
UpAvg = (UpAvg1 * (Length - 1) + UpAmt) / Length;
DownAvg = (DownAvg1 * (Length - 1) + DownAmt) / Length;
End;
If UpAvg + DownAvg <> 0 Then
RSIv = 100 * UpAvg / (UpAvg + DownAvg);
Else
RSIv = 0;
plot1(RSIV);
PlotBaseLine1(30, "기준선 30");
PlotBaseLine2(70, "기준선 70");
즐거운 하루되세요
> 예스매니아 님이 쓴 글입니다.
> 제목 : 문의드립니다.
> 안녕하세요,,,
예전에 RSI일봉지표를 분봉에서 볼 수 있게 제작해주셨는데요,,,
죄송한데,,,
Data2 로 적용할수 있게 제작해주시면 감사하겠습니다.
늘 감사드립니다.
다음글
이전글