커뮤니티
문의드립니다.
2014-03-04 12:14:13
112
글번호 73165
일봉 Will'R 을 분봉에서 볼수있게 해주셨는데요,,,
1. 일봉 Will'R(가격이 아닌 호가 bids-asks이용) 를 분봉에서 볼수 있게,,,
2. 위의 1번을 Data2에 적용가능하도록,,,
해주시면 감사하겠습니다.
늘 감사합니다.
답변 1
예스스탁 예스스탁 답변
2014-03-04 16:57:20
안녕하세요
예스스탁입니다.
1.
Input : Period(14);
Var : WR(0),cnt(0),diff(0),Hv(0),Lv(0);
Array : HH[50](0),LL[50](0);
diff = bids-asks;
if date != date[1] Then{
HH[0] = diff;
LL[0] = diff;
for cnt = 1 to 49{
HH[cnt] = HH[cnt-1][1];
LL[cnt] = LL[cnt-1][1];
}
}
if diff > HH[0] Then
HH[0] = diff;
if diff < LL[0] Then
LL[0] = diff;
if HH[Period] != 0 Then {
Hv = HH[0];
LV = LL[0];
for cnt = 0 to Period-1{
if HH[cnt] > Hv Then
Hv = HH[cnt];
if LL[cnt] < Lv Then
Lv = LL[cnt];
}
WR = (Hv - diff) / (Hv - Lv) * (-100);
plot1(WR);
}
2.
Input : Period(14);
Var : WR(0,data2),cnt(0,data2),diff(0,data2),Hv(0,data2),Lv(0,data2);
Array : HH[50](0,data2),LL[50](0,data2);
diff = data2(bids-asks);
if data2(date != date[1]) Then{
HH[0] = diff;
LL[0] = diff;
for cnt = 1 to 49{
HH[cnt] = HH[cnt-1][1];
LL[cnt] = LL[cnt-1][1];
}
}
if diff > HH[0] Then
HH[0] = diff;
if diff < LL[0] Then
LL[0] = diff;
if HH[Period] != 0 Then {
Hv = HH[0];
LV = LL[0];
for cnt = 0 to Period-1{
if HH[cnt] > Hv Then
Hv = HH[cnt];
if LL[cnt] < Lv Then
Lv = LL[cnt];
}
WR = (Hv - diff) / (Hv - Lv) * (-100);
plot1(WR);
}
즐거운 하루되세요
> 예스매니아 님이 쓴 글입니다.
> 제목 : 문의드립니다.
> 일봉 Will'R 을 분봉에서 볼수있게 해주셨는데요,,,
1. 일봉 Will'R(가격이 아닌 호가 bids-asks이용) 를 분봉에서 볼수 있게,,,
2. 위의 1번을 Data2에 적용가능하도록,,,
해주시면 감사하겠습니다.
늘 감사합니다.
다음글
이전글