커뮤니티
문의 드립니다.
2014-04-28 21:36:13
192
글번호 74735
분봉에서 일봉의 Chaikin's Oscillator 값을 구할려고 합니다.
아래는 Chaikin's Oscillator 의 공식인데요.
Input : SP(3), LP(10);
Var : value(0), value_Accum(0), Ch(0);
value = ((C - L) - (H - C)) / (H - L) * V;
value_Accum = Accum(value);
Ch = ema(value_Accum, SP) - ema(value_Accum, LP);
여기서 중요한건 시스템을 적용하는건
분봉에다 할껀데요, 일봉의 Chaikin's Oscillator 값을
구하는 수식좀 부탁드립니다^^
답변 1
예스스탁 예스스탁 답변
2014-04-29 10:28:56
안녕하세요
예스스탁입니다.
수식은 아래와 같습니다.
다만 문의하신 CO지표는 차트 첫봉부터 누적되는 값을 사용하게 되고
이값을 다시 지수이동평균해서 사용하므로 차트의 봉갯수에 영향을 받는 내용이 많습니다.
실시간 차트는 최대 5000개봉으로 분봉에서 일봉지표를 그리실 경우
실제 일봉에서 보는 값과 날짜가 달라 값이 많이 다르실수 있습니다.
Input : SP(3), LP(10);
Var : Didx(0),value(0),Prevalue(0),Ch(0);
var : Ep1(0), JISU1(0),PreJISU1(0);
var : Ep2(0), JISU2(0),PreJISU2(0);
Ep1 = 2/(SP+1);
Ep2 = 2/(LP+1);
if date != date[1] then {
Didx = Didx + 1;
Prevalue = Prevalue+((DayClose(1) - DayLow(1)) - (DayHigh(1) - DayClose(1))) / (DayHigh(1) - DayLow(1)) * DayVolume(1);
PreJISU1 = JISU1[1];
PreJISU2 = JISU2[1];
}
value = Prevalue+((DayClose - DayLow) - (DayHigh - DayClose)) / (DayHigh - DayLow) * DayVolume;
if Didx <= 1 then{
JISU1 = value;
JISU2 = value;
}
else {
JISU1 = value * EP1 + PreJISU1 * (1-EP1);
JISU2 = value * EP2 + PreJISU2 * (1-EP2);
}
Ch = Jisu1-Jisu2;
plot1(CH,"분봉에서 일봉 Chaikin's Oscillator");
PlotBaseLine1(0);
즐거운 하루되세요
> 무결점 님이 쓴 글입니다.
> 제목 : 문의 드립니다.
> 분봉에서 일봉의 Chaikin's Oscillator 값을 구할려고 합니다.
아래는 Chaikin's Oscillator 의 공식인데요.
Input : SP(3), LP(10);
Var : value(0), value_Accum(0), Ch(0);
value = ((C - L) - (H - C)) / (H - L) * V;
value_Accum = Accum(value);
Ch = ema(value_Accum, SP) - ema(value_Accum, LP);
여기서 중요한건 시스템을 적용하는건
분봉에다 할껀데요, 일봉의 Chaikin's Oscillator 값을
구하는 수식좀 부탁드립니다^^
다음글
이전글