커뮤니티
옵션에서 특정값 구하기
2014-07-01 11:03:22
185
글번호 76262
안녕하세요? 옵션 분봉차트에서 다음값 구현이 가능한지요?
1. 당월물 시작일의 저가
2. 당월물 전체의 최고값과 최저값
3. 당월물 일봉 고/저가 평균값 아니면 종가기준 평균값
4. 전월 전체 최고값과 최저값.
또 보조차트 data2에 대한 1,2,3,4 값을 구하는 수식을 부탁합니다.
감사합니다.
답변 1
예스스탁 예스스탁 답변
2014-07-01 14:56:08
안녕하세요
예스스탁입니다.
1.
var : dcnt(0),V1(0),H1(0),L1(0),H2(0),L2(0),Hsum(0),Lsum(0),Hmav(0),Lmav(0);
var : nday(0),week(0),cond1(false);
nday = date - int(date/100)*100;
week = DayOfWeek(date);
if nday >= 8 and nday <= 14 and week == 4 then
Cond1 = True;
Else
Cond1 = false;
if (Cond1 == false and cond1[1] == true and date != date[1]) or index == 0 Then{
dcnt = 0;
Hsum = 0;
Lsum = 0;
H1 = H;
L1 = L;
H2 = H1[1];
L2 = L1[1];
}
if date != date[1] Then{
dcnt = dcnt+1;
if dcnt >= 2 Then{
Hsum = Hsum + dayhigh(1);
Lsum = Lsum + daylow(1);
}
}
Hmav = (Hsum+dayhigh)/Dcnt;
Lmav = (Lsum+dayLow)/Dcnt;
if dcnt == 1 Then
v1 = daylow;
if H > H1 Then
H1 = H;
if L < L1 Then
L1 = L;
plot1(V1,"당월 시작일저가");
plot2(H1,"당월 최고가");
plot3(L1,"당월 최저가");
plot4(Hmav,"당월 최고가 평균");
plot5(Lmav,"당월 최저가 평균");
plot6(H2,"전월물 최고가");
plot7(L2,"전월물 최저가");
2. data2
var : dcnt(0,data2),V1(0,data2),H1(0,data2),L1(0,data2);
var : H2(0,data2),L2(0,data2),Hsum(0,data2),Lsum(0,data2),Hmav(0,data2),Lmav(0,data2);
var : nday(0,data2),week(0,data2),cond1(false,data2);
nday = data2(date - int(date/100)*100);
week = data2(DayOfWeek(date));
if nday >= 8 and nday <= 14 and week == 4 then
Cond1 = True;
Else
Cond1 = false;
if data2((Cond1 == false and cond1[1] == true and date != date[1]) or index == 0) Then{
dcnt = 0;
Hsum = 0;
Lsum = 0;
H1 = data2(H);
L1 = data2(L);
H2 = H1[1];
L2 = L1[1];
}
if data2(date != date[1]) Then{
dcnt = dcnt+1;
if dcnt >= 2 Then{
Hsum = Hsum + data2(highD(1));
Lsum = Lsum + data2(lowD(1));
}
}
Hmav = (Hsum+data2(highD(0)))/Dcnt;
Lmav = (Lsum+data2(LowD(0)))/Dcnt;
if dcnt == 1 Then
v1 = data2(LowD(0));
if data2(H) > H1 Then
H1 = data2(H);
if data2(L) < L1 Then
L1 = data2(L);
plot1(V1,"당월 시작일저가");
plot2(H1,"당월 최고가");
plot3(L1,"당월 최저가");
plot4(Hmav,"당월 최고가 평균");
plot5(Lmav,"당월 최저가 평균");
plot6(H2,"전월물 최고가");
plot7(L2,"전월물 최저가");
즐거운 하루되세요
> khkwon 님이 쓴 글입니다.
> 제목 : 옵션에서 특정값 구하기
> 안녕하세요? 옵션 분봉차트에서 다음값 구현이 가능한지요?
1. 당월물 시작일의 저가
2. 당월물 전체의 최고값과 최저값
3. 당월물 일봉 고/저가 평균값 아니면 종가기준 평균값
4. 전월 전체 최고값과 최저값.
또 보조차트 data2에 대한 1,2,3,4 값을 구하는 수식을 부탁합니다.
감사합니다.
이전글