커뮤니티
다중 macd 문의
2014-10-02 15:06:28
183
글번호 79053
한 차트의
1분봉에서 3분,5분,10분,30분,60분의 macd(12.26.9)를 거래량 위치에서 같이,
30틱차트에서 60틱,120틱,180틱,240틱의 macd(12.26.9)를 거래량 위치에서 같이 볼수있는
수식도 부탁드립니다 .
중복 죄송합니다.
미리 감사드립니다.
답변 1
예스스탁 예스스탁 답변
2014-10-06 14:29:52
안녕하세요
예스스탁입니다.
아래 2개의 식을 만드시고 중복적용해서 보시면 됩니다.
지표는 동일이름으로 여러번 적용이 됩니다.
적용하실때 지표속성에서 외부변수 Ntime이나 N값을 다르게 하셔서 적용하시면 됩니다.
1. 분봉에서 타분봉
Input : Ntime(10),Period1(12),Period2(26),Period3(9);
Var : Ep1(0), JISU1(0), DINDEX1(0), PreJISU1(0);
Var : Ep2(0), JISU2(0), PreJISU2(0);
Var : Ep3(0), JISU3(0), PreMACDSIG(0),TF(0);
var : MACDVal(0),MACDSig(0);
Ep1 = 2/(Period1+1);
Ep2 = 2/(Period2+1);
Ep3 = 2/(Period3+1);
TF = TimeToMinutes(stime)%Ntime;
if dayindex == 0 or (TF < TF[1] and stime > stime[1]) Then{
DINDEX1 = DINDEX1 + 1;
PreJISU1 = JISU1[1];
PreJISU2 = JISU2[1];
PreMACDSIG = MACDSIG[1];
}
if DINDEX1 <= 1 then {
JISU1 = C;
JISU2 = C;
MACDVal = JiSu1-Jisu2;
MACDSIG = MACDVal;
}
else{
JISU1 = C * EP1 + PreJISU1 * (1-EP1);
JISU2 = C * EP2 + PreJISU2 * (1-EP2);
MACDVal = JiSu1-Jisu2;
MACDSIG = MACDVal * EP3 + PreMACDSIG * (1-EP3);
}
plot1(MACDVal);
plot2(MACDsig);
PlotBaseLine1(0);
2. 틱봉에서 N배높은 틱봉의 MACD값
Input : N(2),Period1(12),Period2(26),Period3(9);
Var : Ep1(0), JISU1(0), DINDEX1(0), PreJISU1(0);
Var : Ep2(0), JISU2(0), PreJISU2(0);
Var : Ep3(0), JISU3(0), PreMACDSIG(0),TF(0);
var : MACDVal(0),MACDSig(0);
Ep1 = 2/(Period1+1);
Ep2 = 2/(Period2+1);
Ep3 = 2/(Period3+1);
TF = dayindex%N;
if dayindex == 0 or (TF < TF[1]) Then{
DINDEX1 = DINDEX1 + 1;
PreJISU1 = JISU1[1];
PreJISU2 = JISU2[1];
PreMACDSIG = MACDSIG[1];
}
if DINDEX1 <= 1 then {
JISU1 = C;
JISU2 = C;
MACDVal = JiSu1-Jisu2;
MACDSIG = MACDVal;
}
else{
JISU1 = C * EP1 + PreJISU1 * (1-EP1);
JISU2 = C * EP2 + PreJISU2 * (1-EP2);
MACDVal = JiSu1-Jisu2;
MACDSIG = MACDVal * EP3 + PreMACDSIG * (1-EP3);
}
plot1(MACDVal);
plot2(MACDsig);
PlotBaseLine1(0);
즐거운 하루되세요
> 정일집중 님이 쓴 글입니다.
> 제목 : 다중 macd 문의
> 한 차트의
1분봉에서 3분,5분,10분,30분,60분의 macd(12.26.9)를 거래량 위치에서 같이,
30틱차트에서 60틱,120틱,180틱,240틱의 macd(12.26.9)를 거래량 위치에서 같이 볼수있는
수식도 부탁드립니다 .
중복 죄송합니다.
미리 감사드립니다.