커뮤니티
일봉주봉지표
2014-12-20 16:23:06
129
글번호 81521
안녕하십니까.
일봉에서 일봉 + 주봉 지표를 같이 나타내고 싶습니다.
1. 지수이평의 일봉/주봉값을 (P1,P2,P3) 나타내는데
각각 상승시 하락시 색깔을 다르게함.
2. MACD의 일봉/주봉값을 나타내는데 상,하 기준선을 추가하고
싶습니다.
3.스토케스틱 일봉/주봉값을 나타내는데 상,하 기준선을 추가하고
싶습니다.
미리 감사를 드립니다.
수고하십시요
답변 1
예스스탁 예스스탁 답변
2014-12-22 10:04:47
안녕하세요
예스스탁입니다.
1.
Input : P1(5),P2(20),P3(60);
var : DINDEX(0);
Var : Ep1(0), WJISU1(0), WPreJISU1(0);
Var : Ep2(0), WJISU2(0), WPreJISU2(0);
Var : Ep3(0), wJISU3(0), WPreJISU3(0);
var : Jisu1(0),Jisu2(0),Jisu3(0);
Ep1 = 2/(P1+1);
Ep2 = 2/(P2+1);
Ep3 = 2/(P3+1);
if dayofweek(date) < dayofweek(date[1]) then {
DINDEX = DINDEX + 1;
WPreJISU1 = WJISU1[1];
WPreJISU2 = WJISU2[1];
WPreJISU3 = WJISU3[1];
}
if DINDEX <= 1 then{
WJISU1 = C;
WJISU2 = C;
WJISU3 = C;
}
else{
WJISU1 = C * EP1 + WPreJISU1 * (1-EP1);
WJISU2 = C * EP2 + WPreJISU2 * (1-EP2);
WJISU3 = C * EP3 + WPreJISU3 * (1-EP3);
if WJISU1 > WPreJISU1 Then
plot1(WJISU1,"지수이동평균1",RED);
Else
plot1(WJISU1,"지수이동평균1",BLUE);
if WJISU2 > WPreJISU2 Then
plot2(WJISU2,"지수이동평균2",RED);
Else
plot2(WJISU2,"지수이동평균2",BLUE);
if WJISU3 > WPreJISU3 Then
plot3(WJISU3,"지수이동평균3",RED);
Else
plot3(WJISU3,"지수이동평균3",BLUE);
}
JISU1 = ema(C,P1);
JISU2 = ema(C,P2);
JISU3 = ema(C,P3);
if JISU1 > JISU1[1] Then
plot4(JISU1,"지수이평1",RED);
Else
plot4(JISU1,"지수이평1",blue);
if JISU2 > JISU2[1] Then
plot5(JISU2,"지수이평2",RED);
Else
plot5(JISU2,"지수이평2",blue);
if JISU3 > JISU3[1] Then
plot6(JISU3,"지수이평3",RED);
Else
plot6(JISU3,"지수이평3",blue);
2.
Input : Period1(12),Period2(26),Period3(9),중심(0),상단기준(1),하단기준(-1);
var : DINDEX1(0);
Var : Ep1(0), wJISU1(0), wPreJISU1(0);
Var : Ep2(0), wJISU2(0), wPreJISU2(0);
Var : Ep3(0), wJISU3(0), wPreMACDSIG(0);
var : wMACDVal(0),wMACDSig(0);
var : MACDVal(0),MACDSig(0);
Ep1 = 2/(Period1+1);
Ep2 = 2/(Period2+1);
Ep3 = 2/(Period3+1);
if DayOfWeek(sdate) < DayOfWeek(sdate[1]) Then{
DINDEX1 = DINDEX1 + 1;
wPreJISU1 = wJISU1[1];
wPreJISU2 = wJISU2[1];
wPreMACDSIG = wMACDSIG[1];
}
if DINDEX1 <= 1 then {
wJISU1 = C;
wJISU2 = C;
wMACDVal = wJiSu1-wJisu2;
wMACDSIG = wMACDVal;
}
else{
wJISU1 = C * EP1 + wPreJISU1 * (1-EP1);
wJISU2 = C * EP2 + wPreJISU2 * (1-EP2);
wMACDVal = wJiSu1-wJisu2;
wMACDSIG = wMACDVal * EP3 + wPreMACDSIG * (1-EP3);
}
MACDVal = MACD(Period1,Period2);
MACDSig = ema(MACDval,Period3);
plot1(wMACDVal);
plot2(wMACDsig);
plot3(MACDVal);
plot4(MACDsig);
PlotBaseLine1(중심,"중심");
PlotBaseLine2(상단기준,"상단기준");
PlotBaseLine3(하단기준,"하단기준");
3
input : Period1(10), Period2(5), Period3(5),하단(20),상단(80);
var : count(0),cnt(0),Ep1(0), EP2(0),DINDEX(0);
var : whighVal(0), wlowVal(0), wStoFastK(0);
var : wStoK(0), wStoD(0), wPreStoK(0), wPreStoD(0);
var : stok(0),stod(0);
Array : wH[100](0),wL[100](0);
Ep1 = 2/(Period2+1);
Ep2 = 2/(Period3+1);
if DayOfWeek(sdate) < DayOfWeek(sdate[1]) Then{
DINDEX = DINDEX + 1;
wH[0] = H;
wL[0] = L;
for cnt = 1 to 99{
wH[cnt] = wH[cnt-1][1];
wL[cnt] = wL[cnt-1][1];
}
wPreStoK = wStoK[1];
wPreStoD = wStoD[1];
}
if H > wH[0] Then
wH[0] = H;
if L < wL[0] Then
wL[0] = L;
whighVal = wH[0];
wlowVal = wL[0];
for count = 0 to Period1-1 {
if wH[count] > whighVal then
whighVal = wH[count];
if wL[count] < wlowVal then
wlowVal = wL[count];
}
wStoFastK = (C-wlowVal)/(whighVal-wlowVal)*100;
if DINDEX <= 1 then {
wStoK = wStoFastK ;
wStoD = wStoK ;
}
else{
wStoK = wStoFastK * EP1 + wPreStoK * (1-EP1);
wStoD = wStoK * EP2 + wPreStoD * (1-EP2);
}
stok = StochasticsK(Period1,Period2);
stod = StochasticsD(Period1,Period2,Period3);
plot1(StoK,"스토k");
plot2(StoD,"스토D");
plot3(wStoK,"주봉스토k");
plot4(wStoD,"주봉스토D");
PlotBaseLine1(하단);
PlotBaseLine2(상단);
즐거운 하루되세요
> 미수예스 님이 쓴 글입니다.
> 제목 : 일봉주봉지표
> 안녕하십니까.
일봉에서 일봉 + 주봉 지표를 같이 나타내고 싶습니다.
1. 지수이평의 일봉/주봉값을 (P1,P2,P3) 나타내는데
각각 상승시 하락시 색깔을 다르게함.
2. MACD의 일봉/주봉값을 나타내는데 상,하 기준선을 추가하고
싶습니다.
3.스토케스틱 일봉/주봉값을 나타내는데 상,하 기준선을 추가하고
싶습니다.
미리 감사를 드립니다.
수고하십시요