커뮤니티
문의드립니다
2015-01-26 05:45:57
127
글번호 82600
시스템 자동매매에 적용하고자 합니다. 코딩 부탁드려요..
★ 자동매수조건 (전부 and 조건입니다)
1. 대상 : 코스피/코스닥 (ETF, 지수관련 종목 제외)
2. 매수시간 : 09:00:00 ~ 11:00:00
3. 종목가격 : 15,000원 ~ 50,000원
4. 2일평균거래대금(당일제외) : 25억원이상
5. 체결강도 : 125%이상
6. 일봉상 : 전일동시간대비 거래량비율 : 225%이상
7. 일봉상 : 전일종가대비 당일시가등락률 : 0.1%이상 ~ 5%이하
8. 일봉 : 전일종가대비 당일종가등락률 : 5%이하
9. 일봉 이평선 : 당일시가 < 가중이평 3일 이평선
당일종가 > 가중이평 3일 이평선
당일종가 >= 가중이평 5일 이평선
10. 5분봉 : 시가 < 종가
11. 가격-이평선이격도 : 당일현재종가가 5일 이평선과 이격도가 105%이하
=> 매수 : 위조건(전부 and조건)이 다 맞을때의 현재가
★ 자동매도조건
1. 매도시간 : 11:30:00 ~ 14:00:00
2. 중복매수는 없음 (당일 매수해서 보유된 종목은 추가매수하지 않음)
3. 이익실현 : 매수가대비 5%
손절 : 당일시가
트레일링 : 매수후 실시간 최고점대비 -2%하락시 매도
강제청산 : 14:30:00 처리가 안된 종목 모두 처리
시간이 걸리고 많이 복잡하시겠지만.. 저에게는 굉장히 중요한 부분이라서요..
꼭 부탁드립니다. 코딩부탁드립니다
감사합니다.
답변 1
예스스탁 예스스탁 답변
2015-01-26 14:31:32
안녕하세요
예스스탁입니다.
var : dm(0),dm1(0),dm2(0),upv(0),dnv(0);
var : cnt(0),PreDayV(0);
Input : P1(3),P2(5),Period(5);
var : Sum1(0),CSum1(0),DayWMA1(0);
var : Sum2(0),CSum2(0),DayWMA2(0);
var : sum(0),mav(0),count(0);
if date != date[1] Then{
DM = 0;
DM1 = Dm[1];
DM2 = Dm1[1];
upv = 0;
dnv = 0;
}
DM = DM+Money;
upv = upv+Upvol;
dnv = dnv+DownVol;
#일봉 가중이평 계산
Sum1 = 0;
CSum1 = 0;
Sum2 = 0;
CSum2 = 0;
For cnt = 0 To P2{
if cnt < P1 then{
Sum1 = Sum1 + DayClose(cnt) * (P1 - cnt);
CSum1 = CSum1 + P1 - cnt;
}
if cnt < P2 then{
Sum2 = Sum2 + DayClose(cnt) * (P2 - cnt);
CSum2 = CSum1 + P2 - cnt;
}
}
If CSum1 > 0 Then
DayWMA1 = Sum1 / CSum1;
Else
DayWMA1 = 0;
If CSum2 > 0 Then
DayWMA2 = Sum2 / CSum2;
Else
DayWMA2 = 0;
#전일 동시간대 누적거래량 계산
for cnt = 1 to 500 {
if stime <= stime[cnt] and sdate != sdate[cnt] then{
PreDayV = DayVolume[cnt];
cnt = 1000;
}
}
#일봉 단순이평 계산
sum = 0;
for cnt = 0 to Period-1{
sum = sum+DayClose(cnt);
}
mav = sum/Period;
#당일 진입횟수
count = 0;
for cnt = 0 to 20{
if sdate == EntryDate(cnt) Then
count = count+1;
}
mav = sum/Period;
if MarketPosition == 0 and
count == 0 and
stime >= 090000 and stime <= 110000 And
C >= 15000 and C <= 50000 And
(DM1+DM2)/2 >= 2500000000 And
Upv/DnV*100 >= 125 And
DayVolume >= PreDayV*2.25 and
dayopen >= DayClose(1)*1.001 and dayopen <= DayClose(1)*1.05 and
DayClose <= DayClose(1)*1.05 And
dayopen < DayWMA1 And
DayClose > DayWMA1 And
DayClose >= DayWMA2 And
O < C And
C/mav*100 <= 105 Then
buy();
if MarketPosition == 1 And
stime >= 113000 and stime < 140000 then{
ExitLong("bL",AtStop,dayopen);
ExitLong("bP",Atlimit,EntryPrice*1.05);
ExitLong("btr",AtStop,highest(H,BarsSinceEntry)*0.98);
}
SetStopEndofday(143000);
시스템은 종목검색과는 연계되지 않습니다.
거래를 원하시는 종목의 차트를 여시고
위식을 시스템식으로 작성해 적용하시면 됩니다.
즐거운 하루되세요
> HI_my***** 님이 쓴 글입니다.
> 제목 : 문의드립니다
> 시스템 자동매매에 적용하고자 합니다. 코딩 부탁드려요..
★ 자동매수조건 (전부 and 조건입니다)
1. 대상 : 코스피/코스닥 (ETF, 지수관련 종목 제외)
2. 매수시간 : 09:00:00 ~ 11:00:00
3. 종목가격 : 15,000원 ~ 50,000원
4. 2일평균거래대금(당일제외) : 25억원이상
5. 체결강도 : 125%이상
6. 일봉상 : 전일동시간대비 거래량비율 : 225%이상
7. 일봉상 : 전일종가대비 당일시가등락률 : 0.1%이상 ~ 5%이하
8. 일봉 : 전일종가대비 당일종가등락률 : 5%이하
9. 일봉 이평선 : 당일시가 < 가중이평 3일 이평선
당일종가 > 가중이평 3일 이평선
당일종가 >= 가중이평 5일 이평선
10. 5분봉 : 시가 < 종가
11. 가격-이평선이격도 : 당일현재종가가 5일 이평선과 이격도가 105%이하
=> 매수 : 위조건(전부 and조건)이 다 맞을때의 현재가
★ 자동매도조건
1. 매도시간 : 11:30:00 ~ 14:00:00
2. 중복매수는 없음 (당일 매수해서 보유된 종목은 추가매수하지 않음)
3. 이익실현 : 매수가대비 5%
손절 : 당일시가
트레일링 : 매수후 실시간 최고점대비 -2%하락시 매도
강제청산 : 14:30:00 처리가 안된 종목 모두 처리
시간이 걸리고 많이 복잡하시겠지만.. 저에게는 굉장히 중요한 부분이라서요..
꼭 부탁드립니다. 코딩부탁드립니다
감사합니다.
다음글
이전글