커뮤니티
시스템식 문의드립니다.
2015-01-28 22:39:41
122
글번호 82760
일봉과 주봉을 동시에 고려하는 식을 만들어 주셨으면 합니다.
※ 아래 구매조건에서 거래량과 엔벨로프(20,20) 와 60 주선은 반드시 일봉이 아닌
주봉기준의 지표 및 식으로 부탁드립니다.
→ 일단위의 거래량과 엔벨로프 60일선 식은 알고있으나
주단위로의 거래량과 엔벨로프 60주선을 만드는 식을 몰라 질문 드리는겁니다..ㅠ
1.구매조건
주봉이 과거 8 주봉 동안 바로 전주 주봉 거래량보다 50배 이상 상승된 이력이 있으며,
과거 8 주봉 동안의 주봉 고가가 엔벨로프(20,20) 저항선 보다 높았던 이력이 있고,
주봉 종가가 60 주선 아래에 있으며,
일봉 종가가 120일선 아래에 있으면
다음주 시초가에 구매
2.판매조건
(이번주 주봉 고가가 구매날짜기준 과거 8 주봉 중의 고가대비 90% 까지 올랐거나) [or]
(구매가 보다 높으면서 [and] 엔벨로프(20,20) 저항선 을 넘었다면)
다음주 시초가에 판매
다시한번 거래량, 엔벨로프, 60주선은 주단위로 봤을때의 지표로 해주시길.. 부탁드립니다.
감사합니다~!
답변 1
예스스탁 예스스탁 답변
2015-01-29 11:47:34
안녕하세요
예스스탁입니다.
일봉차트를 여시고 식을 적용하셔야 합니다.
input : N(8),Period(20),per(20),P(60);
var : cnt(0),Vcnt(0),sum1(0),sum2(0),weekmav(0),mav(0),Hcnt(0),HH(0);
Array : weekV[100](0),weekC[100](0),weekH[100](0),weekEVup[100](0);
if DayOfWeek(sdate) < DayOfWeek(sdate[1]) Then{
weekV[0] = 0;
WeekH[0] = H;
for cnt = 1 to 99{
weekV[cnt] = weekV[cnt-1][1];
weekC[cnt] = weekC[cnt-1][1];
weekH[cnt] = weekH[cnt-1][1];
weekEVup[cnt] = weekEVup[cnt-1][1];
}
}
weekC[0] = c;
weekV[0] = weekV[0]+V;
if H > weekH[0] Then
WeekH[0] = H;
#주봉 엔벨로프 상단계산
if weekC[Period] > 0 then{
sum1 = 0;
for cnt = 0 to Period-1{
sum1 = sum1+weekC[cnt];
}
weekEVup[0] = (sum1/Period)+ (sum1/Period)*(per/100);
}
#주봉 60이평 계산
if weekC[P] > 0 then{
sum2 = 0;
for cnt = 0 to P-1{
sum2 = sum2+weekC[cnt];
}
weekmav = sum2/P;
}
#일봉 120이평
mav = ma(c,120);
if weekV[N] > 0 and weekEVup[N] > 0 and weekC[P] > 0 Then{
#과거 8주간 전주대비 거래량이 50배이상을 기록한 횟수 계산
Vcnt = 0;
for cnt = 1 to N{
if weekV[cnt] > weekV[cnt+1]*50 Then
Vcnt = Vcnt+1;
}
#과거 8주간 주봉고가가 엔벨로프상단보다 큰 횟수 계산
Hcnt = 0;
for cnt = 1 to N{
if WeekH[cnt] > WeekEVup[cnt] Then
Hcnt = Hcnt+1;
}
#현재 무포지션
if MarketPosition == 0 and
#과거 8주 안에 거래량50배 증가가 한번이상 있고
Vcnt >= 1 and
#과거 8주 안에 주봉고가가 엔벨로프 상단보다 큰 경우가 한번이상 있고
Hcnt >= 1 and
#현재종가는 주봉60이평보다 작고
C < Weekmav and
#현재봉가는 일봉120이평보다 작고
C < mav and
#오늘 금요일이면 다음날시가에 매수
DayOfWeek(sdate) == 5 Then{
buy("b",AtMarket);
}
}
if MarketPosition == 1 Then{
#진입시점 이전 8주 최고가
if MarketPosition[1] != 1 Then{
HH = WeekH[1];
for cnt = 1 to N{
if WeekH[cnt] > HH Then
HH = WeekH[cnt];
}
}
#금요일이고 아래조건 만족하면 다음날 시가에 청산
if DayOfWeek(sdate) == 5 and
#이번주 고가가 8주최고가+90% 이상 상승하거나
(WeekH[0] >= HH*1.9 Or
#종가가 진입가보다 큰상태에서 종가가 주봉엔벨로프상단보다 크면 청산
(C > EntryPrice and C > WeekEvup[0])) Then
ExitLong("bx",AtMarket);
}
즐거운 하루되세요
> 돼끼 님이 쓴 글입니다.
> 제목 : 시스템식 문의드립니다.
> 일봉과 주봉을 동시에 고려하는 식을 만들어 주셨으면 합니다.
※ 아래 구매조건에서 거래량과 엔벨로프(20,20) 와 60 주선은 반드시 일봉이 아닌
주봉기준의 지표 및 식으로 부탁드립니다.
→ 일단위의 거래량과 엔벨로프 60일선 식은 알고있으나
주단위로의 거래량과 엔벨로프 60주선을 만드는 식을 몰라 질문 드리는겁니다..ㅠ
1.구매조건
주봉이 과거 8 주봉 동안 바로 전주 주봉 거래량보다 50배 이상 상승된 이력이 있으며,
과거 8 주봉 동안의 주봉 고가가 엔벨로프(20,20) 저항선 보다 높았던 이력이 있고,
주봉 종가가 60 주선 아래에 있으며,
일봉 종가가 120일선 아래에 있으면
다음주 시초가에 구매
2.판매조건
(이번주 주봉 고가가 구매날짜기준 과거 8 주봉 중의 고가대비 90% 까지 올랐거나) [or]
(구매가 보다 높으면서 [and] 엔벨로프(20,20) 저항선 을 넘었다면)
다음주 시초가에 판매
다시한번 거래량, 엔벨로프, 60주선은 주단위로 봤을때의 지표로 해주시길.. 부탁드립니다.
감사합니다~!
다음글