커뮤니티
검토해주세요!!
2015-02-10 21:42:12
148
글번호 83128
NO.40355 입니다
다음의 조건이 충족 될 수 있도록 수정 하여 주시면 좋겠습니다.
1. 추세선이 안보입니다. 추세선이 차트에 생성 되도록 하고,
2. 변수 left 와 right가 동일한 하나의 변수(N)가 될 수 있도록 설정 하고자 합니다.
답변 1
예스스탁 예스스탁 답변
2015-02-11 10:26:08
안녕하세요
예스스탁입니다.
input : N(3);
var : cnt(0),T(0),BTL(0),STL(0);
Array : HV[10](0),LV[10](0);
Array : HD[10](0),LD[10](0);
Array : HT[10](0),LT[10](0);
if SwingHigh(1,h,N,N,N+N+1) != -1 Then{
T = 1;
HD[0] = sdate[N];
HT[0] = sTime[N];
Hv[0] = H[N];
for cnt = 1 to 9{
HD[cnt] = HD[cnt-1][1];
HT[cnt] = HT[cnt-1][1];
HV[cnt] = HV[cnt-1][1];
}
Condition1 = false;
if HV[9] > 0 Then{
for cnt = 1 to 9{
if Condition1 == false and HV[cnt] > HV[0] Then{
Condition1 = true;
var1 = HD[cnt];
var2 = HT[cnt];
var3 = HV[cnt];
}
}
if Condition1 == true Then{
TL_SetExtRight(BTL,false);
BTL = TL_new(var1,var2,var3,HD[0],HT[0],HV[0]);
TL_SetExtRight(BTL,true);
TL_SetColor(BTL,RED);
}
}
}
if SwingLow(1,h,N,N,N+N+1) != -1 Then{
T = -1;
LD[0] = sdate[N];
LT[0] = stime[N];
LV[0] = L[N];
for cnt = 1 to 9{
LD[cnt] = LD[cnt-1][1];
LT[cnt] = LT[cnt-1][1];
LV[cnt] = LV[cnt-1][1];
}
Condition2 = false;
if LV[9] > 0 Then{
for cnt = 1 to 9{
if Condition2 == false and LV[cnt] < LV[0] Then{
Condition2 = true;
var4 = LD[cnt];
var5 = LT[cnt];
var6 = LV[cnt];
}
}
if Condition2 == true Then{
TL_SetExtRight(STL,false);
STL = TL_new(var4,var5,var6,LD[0],LT[0],LV[0]);
TL_SetExtRight(STL,true);
TL_SetColor(STL,blue);
}
}
}
if Condition1 == true and T == 1 And
C >= TL_GetValue(BTL,sdate,stime) And
C[1] < TL_GetValue(BTL,sdate[1],stime[1]) Then
buy();
if Condition2 == true and T == -1 And
C <= TL_GetValue(STL,sdate,stime) And
C[1] > TL_GetValue(STL,sdate[1],stime[1]) Then
sell();
if MarketPosition == 1 Then
ExitLong("bx",atlimit,highest(H,6));
if MarketPosition == -1 Then
ExitShort("sx",atlimit,Lowest(L,6));
첨부된 그림은 선물 10분봉에 적용한 화면입니다.
즐거운 하루되세요
> 너무조아 님이 쓴 글입니다.
> 제목 : 검토해주세요!!
> NO.40355 입니다
다음의 조건이 충족 될 수 있도록 수정 하여 주시면 좋겠습니다.
1. 추세선이 안보입니다. 추세선이 차트에 생성 되도록 하고,
2. 변수 left 와 right가 동일한 하나의 변수(N)가 될 수 있도록 설정 하고자 합니다.