커뮤니티
지표변환방법
2015-04-20 11:09:07
181
글번호 85179
안녕하세요.
스토케스틱533의 일봉,60분봉,30분봉 3가지를 1분봉에서 볼 수 있게
하는 방법을 알려주시면 감사하겠습니다.
답변 1
예스스탁 예스스탁 답변
2015-04-20 16:38:19
안녕하세요
예스스탁입니다.
input : Atime1(30),Atime2(60),Sto1(5), Sto2(3), Sto3(3);
var : TF1(0),TF2(0),Ep1(0), EP2(0),cnt(0);
var : hVal1(0), lVal1(0), FK1(0), SK1(0), SD1(0);
var : didx1(0), PreSK1(0), PreSD1(0);
Array : H1[50](0),L1[50](0);
var : hVal2(0), lVal2(0), FK2(0), SK2(0), SD2(0);
var : didx2(0), PreSK2(0), PreSD2(0);
Array : H2[50](0),L2[50](0);
var : hVal3(0), lVal3(0), FK3(0), SK3(0), SD3(0);
var : PreSK3(0), PreSD3(0);
TF1 = TimeToMinutes(stime)%Atime1;
TF2 = TimeToMinutes(stime)%Atime2;
Ep1 = 2/(sto2+1);
Ep2 = 2/(Sto3+1);
if dayindex == 0 or (TF1 < TF1[1] and stime > stime[1]) Then{
H1[0] = H;
L1[0] = L;
for cnt = 1 to 49{
H1[cnt] = H1[cnt-1][1];
L1[cnt] = L1[cnt-1][1];
}
didx1 = didx1 + 1;
PreSK1 = SK1[1];
PreSD1 = SD1[1];
}
if H > H1[0] Then
H1[0] = H;
if L < L1[0] Then
L1[0] = L;
hVal1 = H1[0];
lVal1 = L1[0];
for cnt = 0 to sto1-1 {
if H1[cnt] > hVal1 then
hVal1 = H1[cnt];
if L1[cnt] < lval1 then
LVal1 = L1[cnt];
}
FK1 = (C-lVal1)/(hVal1-lVal1)*100;
if didx1 <= 1 then{
SK1 = FK1 ;
SD1 = SK1;
}
else{
SK1 = FK1 * EP1 + PreSK1 * (1-EP1);
SD1 = SK1 * EP2 + PreSD1 * (1-EP2);
}
if dayindex == 0 or (TF2 < TF2[1] and stime > stime[1]) Then{
H2[0] = H;
L2[0] = L;
for cnt = 1 to 49{
H2[cnt] = H2[cnt-1][1];
L2[cnt] = L2[cnt-1][1];
}
didx2 = didx2 + 1;
PreSK2 = SK2[1];
PreSD2 = SD2[1];
}
if H > H2[0] Then
H2[0] = H;
if L < L2[0] Then
L2[0] = L;
hVal2 = H2[0];
lVal2 = L2[0];
for cnt = 0 to Sto1-1 {
if H2[cnt] > hVal2 then
hVal2 = H2[cnt];
if L2[cnt] < lval2 then
LVal2 = L2[cnt];
}
FK2 = (C-lVal2)/(hVal2-lVal2)*100;
if didx2 <= 1 then{
SK2 = FK2;
SD2 = SK2;
}
else{
SK2 = FK2 * EP1 + PreSK2 * (1-EP1);
SD2 = SK2 * EP2 + PreSD2 * (1-EP2);
}
if date != date[1] then {
PreSK3 = SK3[1];
PreSD3 = SD3[1];
}
#N일간 최고가 및 최저가
hVal3 = dayhigh(0);
lVal3 = daylow(0);
for cnt = 0 to sto1-1 {
if dayHigh(cnt) > hVal3 then
hVal3 = dayhigh(cnt);
if dayLow(cnt) < lVal3 then
lVal3 = dayLow(cnt);
}
fK3 = (C-lVal3)/(hVal3-lVal3)*100;
SK3 = FK3 * EP1 + PreSK3 * (1-EP1);
SD3 = SK3 * EP2 + PreSD3 * (1-EP2);
plot1(SK1);
plot2(SD1);
plot3(SK2);
plot4(SD2);
plot5(SK3,"일봉 SlowK");
plot6(SD3,"일봉 SlowD");
PlotBaseLine1(20);
PlotBaseLine2(80);
즐거운 하루되세요
> 미사일 님이 쓴 글입니다.
> 제목 : 지표변환방법
> 안녕하세요.
스토케스틱533의 일봉,60분봉,30분봉 3가지를 1분봉에서 볼 수 있게
하는 방법을 알려주시면 감사하겠습니다.