커뮤니티
부탁드립니다
2016-02-16 09:50:38
136
글번호 95399
1)46271번 의 최종수정식(월물기준가포함) 을 데이터2참조 사용할수있도록 수식변경부탁드립니다
2) 현재 제공되고잇는 DEMA 이평선 도 데이터2 참조용으로 사용할수있도록 부탁드립니다
3) TSF 이평기준으로 볼린져 밴드처럼 60 이평 승수 1 승수2 승수3(이평 승수 변수처리) 이리 해서 쓸수있도록 부탁드립니다
항상빠른답변과 노고에 거듭감사드립니다 ^^
답변 1
예스스탁 예스스탁 답변
2016-02-16 10:05:01
안녕하세요
예스스탁입니다.
1.
var : nday(0,data2),week(0,data2),cond(false,data2);
var : HH(0,data2),LL(0,data2),RR(0,data2),idx(0,data2),L1(0,data2);
nday = data2(date - int(date/100)*100);
week = data2(DayOfWeek(date));
if nday >= 8 and nday <= 14 and week == 4 then
cond = true;
Else
cond = false;
if data2(date != date[1]) Then{
if cond == false and cond[1] == true Then{
HH = data2(H);
LL = data2(L);
idx = 0;
}
Else
idx = idx+1;
}
if idx == 0 Then
L1 = data2(lowD(0));
if data2(H) > HH Then
HH = data2(H);
if data2(L) < LL Then
LL = data2(L);
RR = (HH+LL)/2;
plot1(HH,"월물고가");
plot2(LL,"월물저가");
plot3(HH-(HH-LL)*0.236,"23.6%");
plot4(HH-(HH-LL)*0.382,"38.2%");
plot5(HH-(HH-LL)*0.500,"50.0%");
plot6(HH-(HH-LL)*0.618,"61.8%");
plot7(HH-(HH-LL)*0.764,"76.4%");
plot8(data2(highD(1)),"전일고가");
plot9(data2(LowD(1)),"전일저가");
plot10(data2((highD(1)+lowD(1))/2),"전일중간");
plot11(DayClose(1),"전일종가");
plot12(L1,"월물기준");
2.
INPUTS: LENGTH1(5),LENGTH2(20),LENGTH3(60);
var : V1(0,data2),V2(0,data2),V3(0,data2);
var : Val1(0,data2),Val2(0,data2),Val3(0,data2);
VAR : DEMA1(0,data2),DEMA2(0,data2),DEMA3(0,data2);
v1= data2(EMA(C,LENGTH1));
val1= data2(EMA(EMa(C,LENGTH1),LENGTH1));
v2= data2(EMA(C,LENGTH2));
val2= data2(EMA(EMa(C,LENGTH2),LENGTH2));
v3= data2(EMA(C,LENGTH3));
val3= data2(EMA(EMa(C,LENGTH3),LENGTH3));
DEMA1 = v1 * 2 - val1;
DEMA2 = v2 * 2 - val2;
DEMA3 = v3 * 2 - val3;
PLOT1(DEMA1, "DEMA1");
PLOT2(DEMA2, "DEMA2");
PLOT3(DEMA3, "DEMA3");
3.
Input : Period(60),d1(1),d2(2),d3(3);
var : TSF(0),SumSqrt(0),cnt(0),stdv(0);
var : BBup1(0),BBup2(0),BBup3(0),BBdn1(0),BBdn2(0),BBdn3(0);
TSF = LRL(C,Period)+LRS(C,Period);
SumSqrt = 0;
For cnt = 0 To Period - 1 Begin
SumSqrt = SumSqrt + (C[cnt] - TSF) * (C[cnt] - TSF);
End;
Stdv = SquareRoot(SumSqrt / Period);
BBup1 = TSF+Stdv*d1;
BBup2 = TSF+Stdv*d2;
BBup3 = TSF+Stdv*d3;
BBdn1 = TSF-Stdv*d1;
BBdn2 = TSF-Stdv*d2;
BBdn3 = TSF-Stdv*d3;
Plot1(TSF,"중단(TSF)") ;
Plot2(BBup1,"상단1") ;
Plot3(BBup2,"상단2") ;
Plot4(BBup3,"상단3") ;
Plot5(BBdn1,"하단1") ;
Plot6(BBdn2,"하단2") ;
Plot7(BBdn3,"하단3") ;
즐거운 하루되세요
> 상승형 님이 쓴 글입니다.
> 제목 : 부탁드립니다
> 1)46271번 의 최종수정식(월물기준가포함) 을 데이터2참조 사용할수있도록 수식변경부탁드립니다
2) 현재 제공되고잇는 DEMA 이평선 도 데이터2 참조용으로 사용할수있도록 부탁드립니다
3) TSF 이평기준으로 볼린져 밴드처럼 60 이평 승수 1 승수2 승수3(이평 승수 변수처리) 이리 해서 쓸수있도록 부탁드립니다
항상빠른답변과 노고에 거듭감사드립니다 ^^
다음글
이전글